根据这些数据在 Gnuplot 中绘制堆叠直方图

Question

数据

Year    Water Power     Wood Power
2025    58.1     41.9
2035    55.8     44.2
2050    50.6     49.4

代码

set style histogram columnstacked; 
set terminal qt size 560,270; 
set grid; 
set offset 1,1,0,0; 
plot 'RES.dat' u 1:3;

这给出了

它以某种方式省略了命令的第一句。我试图通过 plot 'RES.dat' u 3:key(1); 设置密钥但未成功，我认为这不是必需的，因为在 1:3 中，密钥已被假定为由第一列设置。

再次尝试使用代码

set terminal qt size 560,270; 
set grid; set offset 1,1,0,0; 
plot 'RES.dat' u 2 ti col, u 3:key(1) ti col;

但是错了。

我想要

按照手册中的描述堆叠柱子，但总共有 100 个单元。我的实施似乎是错误的。可能的解决方案 here.

如何在 Gnulplot 中获得堆叠直方图？

Answer 1

几件事：

您必须告诉 gnuplot 使用直方图，例如
```
set style data histogram
```
绘制直方图时不得指定 x-value。这是自动选择的（递增整数，从 0 开始）
要使用带空格的列标题，您必须用引号将其括起来。

这是一个完整的工作示例，用于获取列堆叠直方图：

$data <<EOD
Year    "Water Power"     "Wood Power"
2025    58.1     41.9
2035    55.8     44.2
2050    50.6     49.4
EOD

set style histogram columnstacked
set style data histogram 
set key autotitle columnheader
set style fill solid noborder
set boxwidth 0.8
plot $data using 2, '' using 3:key(1)

为了获得行堆叠直方图，您只需要非常小的更改（使用 xtic 而不是 key）：

$data <<EOD
Year    "Water Power"     "Wood Power"
2025    58.1     41.9
2035    55.8     44.2
2050    50.6     49.4
EOD

set style histogram rowstacked
set style data histogram 
set key autotitle columnheader
set style fill solid noborder
set boxwidth 0.8
set offset 0,1,0,0
plot $data using 2:xtic(1), '' using 3

根据这些数据在 Gnuplot 中绘制堆叠直方图

To plot stacked histogram in Gnuplot from this data

plot

gnuplot