Julia 合并排序实现无法正常工作

Question

我不太清楚为什么我的合并排序实现不起作用。

merge_sort 将数组 A 以及起始和最终索引 p 和 r 作为参数。如果我在 A = [1, 64, 64, 315, 14, 2, 3, 4, 5] 上尝试运行 merge_sort(A, 1, 9)，A 将变为 A = [ 1, 1, 1, 1, 1, 2, 2, 4, 5]。我正在尝试使用哨兵来检测 L 和 R 阵列是否已耗尽。

代码如下：

function merge_sort(A, p, r)
    if p < r
        q = floor(Int, (p+r)/2)
        merge_sort(A, p, q)
        merge_sort(A, q+1, r)
        merge(A, p, q, r)
    end
end



function merge(A, p, q, r)
    n1 = q-p+1
    n2 = r-q
    L = []
    R = []

    for i = 1:n1
      push!(L, A[p+1-1])
    end

    for j = 1:n2
      push!(R, A[q+j])
    end

    sentinel = 123456789
    push!(L, sentinel)
    push!(R, sentinel)
    i=1
    j=1

    for k=p:r
      if L[i] <= R[j]
         A[k] = L[i]
         i = i+1
      else
        A[k] = R[j]
        j = j+1

      end
    end
end

Answer 1

您在 push!(L, A[p+1-1]) 中有错字，应该是 push!(L, A[p+i-1])。

这里是你的代码的一个稍微清理过的版本（但我没有尝试完全优化它以保留你的逻辑）：

function merge_sort!(A, p = 1, r = length(A))
    if p < r
        q = div(p+r, 2)
        merge_sort!(A, p, q)
        merge_sort!(A, q+1, r)
        merge!(A, p, q, r)
    end
    A
end

function merge!(A, p, q, r)
    sentinel = typemax(eltype(A))
    L = A[p:q]
    R = A[(q+1):r]
    push!(L, sentinel)
    push!(R, sentinel)
    i, j = 1, 1
    for k in p:r
      if L[i] <= R[j]
          A[k] = L[i]
          i += 1
      else
          A[k] = R[j]
          j += 1
      end
    end
end

Julia 合并排序实现无法正常工作

Julia merge-sort implementation not working correctly

sorting

mergesort

julia