Ada

Question

我的问题很简单，我的输入看起来像这样...

0   0   0   1   1   1  -1  -1  -1   1

我需要将这些值存储到一个数组中，但我无法弄明白。这是我目前所拥有的...

with Ada.Text_IO; use Ada.Text_IO;

procedure Main is
    type arr is array(1..10) of Integer;
    Data : arr;
begin
    for I in 1..arr'Length loop
        Data(I) := Integer'Value(Get_Line);
    end loop;
end Main;

我知道这是错误的，很明显为什么它不起作用。我试图将多个值存储到一个整数中，我需要一种方法来遍历输入或一次加载所有值。你会如何在 Ada 中做到这一点？

Answer 1

您可以使用 Get_Line 将整行作为字符串，然后 Ada.Integer_Text_IO 解析字符串：

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Hello is
    Line : String := Get_Line;
    Value : Integer;
    Last : Positive := 1;
begin

    while Last < Line'Last loop
        Get(Line(Last..Line'Last),Value,Last);
        Put_Line(Value'Image);  -- Save the value to an array here instead
        Last := Last + 1;    -- Needed to move to the next part of the string
    end loop;

end Hello;

之后，您可以在循环中或您喜欢的任何方式将值加载到数组中。

示例输出：

$gnatmake -o hello *.adb
gcc -c hello.adb
gnatbind -x hello.ali
gnatlink hello.ali -o hello
$hello
 0
 0
 0
 1
 1
 1
-1
-1
-1
 1

编辑：添加一个更通用的递归选项。这将从 STDIN 读取一行并递归地将值连接到一个数组中。它使用辅助堆栈在 GNAT 中执行此操作。

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_Io;

procedure Hello is

    -- Need an array return type
    type Integer_Array is array (Positive range <>) of Integer;

    -- Recursive function
    function Get_Ints return Integer_Array is

        Value : Integer;

    begin
        -- Read from STDIN using Integer_Text_IO;
        Get(Value);

        -- Concatinate recursively
        return Integer_Array'(1 => Value) & Get_Ints;

    exception
        -- I found different exceptions with different versions
        -- of GNAT, so using "others" to cover all versions
        when others => 
            -- Using Ada2012 syntax here.  If not using Ada2012
            -- then just declare the Empty variable somewhere
            -- and then return it here
            return Empty : Integer_Array(1..0);

    end Get_Ints;

    Result : Integer_Array := Get_Ints;

begin
  Put_Line("Hello, world!");
  Put_Line(Integer'Image(Result'Length));
  for E of Result loop
    Put(Integer'Image(E) & " ");
  end loop;
end Hello;

Answer 2

如果您知道要阅读 10 个元素，可以像这样更简单地完成：

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Hello is
   A: array (1..10) of Integer;
begin
   for V of A loop
      Get(V);
   end loop;
   for I in A'Range loop
      Put(I, 5);
      Put(": ");
      Put(A(I), 5);
      New_Line;
   end loop;
end Hello;

如果您实际上不知道要提前阅读多少元素，请更新问题。

Answer 3

即使这个问题已经得到解答，我还是想对 Jere 的答案进行一些改进。

使用End_Of_File而不是异常来终止递归更像Ada。另外，它使程序更清晰。

此外，使用尾调用递归而不是正常递归允许编译器执行一些优化。

function Get_Ints(input : in File_Type) return Integer_Array is
    function Get_Ints_Rec(accumulator : in Integer_Array) return Integer_Array is
        value : Integer;
    begin
        if End_Of_File(input) then
            return accumulator;
        else
            begin
               Get(input, value);
            exception
               when Data_Error => -- problem when reading
                  if not End_Of_Line(input) then
                     Skip_Line(input);
                  end if;
                  return Get_Ints_Rec(acc);
            end;
            return Get_Ints_Rec(accumulator & (1 => value));
        end if;
    end Get_Ints_Rec;

    acc : constant Integer_Array(1 .. 0) := (others => 0);
begin
    return Get_Ints_Rec(acc);
end Get_Ints;

Ada - 如何从单行输入中读取数组？

Ada - How do you read an array from a single line of input?