库中的 generateReleaseBuildConfig 错误

Question

Android 工作室项目。我有两个库模块，它们都没有 Java 。我试图抑制 BuildConfig 的生成，因此也没有生成 Java。第一个的 gradle 文件是：

apply plugin: 'com.android.library'

android {
    compileSdkVersion 26

    defaultConfig {
        minSdkVersion 3
        targetSdkVersion 26

        externalNativeBuild {
            ndkBuild {
                abiFilters "armeabi", "x86", "x86_64", "armeabi-v7a", "mips", "arm64-v8a"
                targets "pad", "gif"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
        }
        debug {
            jniDebuggable true
        }
    }

    externalNativeBuild {
        ndkBuild {
            path file("src/main/jni/Android.mk")
        }
    }
}

dependencies {}

afterEvaluate {
    generateReleaseBuildConfig.enabled = false
    generateDebugBuildConfig.enabled = false
}

另一个：

apply plugin: 'com.android.library'

android {
    compileSdkVersion 26

    defaultConfig {
        minSdkVersion 3
        targetSdkVersion 26

        externalNativeBuild {
            ndkBuild {
                abiFilters "armeabi", "x86", "x86_64", "armeabi-v7a", "mips", "arm64-v8a"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
        }
        debug {
            jniDebuggable true
        }
    }

    externalNativeBuild {
        ndkBuild {
            path file("src/main/jni/Android.mk")
        }
    }

    flavorDimensions 'Color'
    productFlavors {
        Blue {
            dimension "Color"
            externalNativeBuild {
                ndkBuild {
                    cppFlags "-DBLUE"
                }
            }
        }
        Red {
            dimension "Color"
            externalNativeBuild {
                ndkBuild {
                    cppFlags "-DRED"
                }
            }
        }
    }
}

dependencies {
    implementation project(':Foo')
}

afterEvaluate {
    generateReleaseBuildConfig.enabled = false
    generateDebugBuildConfig.enabled = false
}

第一个用了一段时间，没问题。第二个是我今天刚创建的，Gradle 同步失败：

A problem occurred configuring project ':LibBar'.

Could not get unknown property 'generateReleaseBuildConfig' for project ':LibBar' of type org.gradle.api.Project.

如果我评论该行，它会抱怨 generateDebugBuildConfig。

第二个模块依赖于第一个模块，不确定是否重要。

两者的清单都只有 package。

我错过了什么？我试过清理项目，使缓存无效。 Gradle 是最新的，Android Studio 也是最新的（刚刚更新）。

Answer 1

构建系统使用当前构建风格修饰步骤名称。所以应该改为：

afterEvaluate {
    generateBlueReleaseBuildConfig.enabled = false
    generateBlueDebugBuildConfig.enabled = false
    generateRedReleaseBuildConfig.enabled = false
    generateRedDebugBuildConfig.enabled = false
}

库中的 generateReleaseBuildConfig 错误

generateReleaseBuildConfig errors out in a library

java

android

gradle

android-gradle-plugin