SELECT 多张表中的一列 MSSQL

Question

易事难事。我想 select 来自不同 table 的一列并将其插入到结果 table 中。基本上，很像一个 union all:

SELECT Email FROM TableA
UNION ALL
Select Email FROM TableB

等等...

但是，我想以自动方式执行此操作。正如我所说，看起来很简单，但我却被它绊倒了。我的代码尝试：

USE MyDatabase

IF OBJECT_ID ('TEMPDB..#Selection') IS NOT NULL DROP TableA #Selection;
SELECT Name AS TableA, ROW_NUMBER() OVER ( ORDER BY (SELECT 1)) AS RowNumb
INTO #Selection
FROM Sys.TableAs AS T
WHERE NAME LIKE '%abc%'
ORDER BY 2


IF OBJECT_ID ('TEMPDB..#Result') IS NOT NULL DROP TableA #Result;
CREATE TableA #Result ( Email VARCHAR (200))

DECLARE @Counter INT 
SET @Counter = 1


WHILE @Counter <= ( SELECT MAX (RowNumb) FROM #Selection )

BEGIN

DECLARE @Table VARCHAR (100)
SET @Table = ( SELECT TableA FROM #Selection WHERE RowNumb = @Counter )

-- PRINT @Table SET @Counter = @Counter + 1 END

    INSERT INTO #Result
    SELECT Email
    FROM @Table

    SET @Counter = @Counter + 1
END

我相信很快就会有人发现我的错误。非常感谢任何指导！

亲切的问候，M.

Answer 1

我（个人）会选择更像这样的东西：

CREATE TABLE #Email (email nvarchar(200));

DECLARE @SQL nvarchar(MAX);

SET @SQL = N'INSERT INTO #Email (Email)' + NCHAR(13) + NCHAR(10) +
           STUFF((SELECT NCHAR(13) + NCHAR(10) + 
                         N'UNION ALL' + NCHAR(13) + NCHAR(10) +
                         N'SELECT CONVERT(nvarchar(200),email)' + NCHAR(13) + NCHAR(10) +
                         N'FROM ' + QUOTENAME(s.[name]) + N'.' + QUOTENAME(t.[name])
                  FROM sys.schemas s
                       JOIN sys.tables t ON s.schema_id = t.schema_id
                       JOIN sys.columns c ON t.object_id = c.object_id
                  WHERE c.[name] = N'Email'
                  FOR XML PATH(N''),TYPE).value(N'.','nvarchar(MAX)'),1,13,N'') + N';';
PRINT @SQL;
EXEC sp_executesql @SQL;

SELECT *
FROM #Email;

DROP TABLE #Email;

这将创建一个动态语句，该语句针对具有列 Email（在当前数据库中）的每个 table 创建一个 UNION ALL 查询，并将该值插入到所述临时 table.然后它 returns 表示来自临时 table 的值（然后处理 table，因为我实际上不知道你要用它做什么）。

SELECT 多张表中的一列 MSSQL

SELECT One column from multiple tables MSSQL

tsql

sql-server

sql-server-2008