包含日期操作的查询函数 [DATE + X 月数]

Question

我正在查询 Google 电子表格，使用相对简单的表达式：

=QUERY(Sheet1!A1:J200, "Select A, J", 1)

此查询在 L 列和 M - 见下图。

接下来我要做的是

向最后 N 个日期中的每一个添加 6 个月；

=IF(M2="","",DATE(YEAR(M2)+0,MONTH(M2)+6,DAY(M2)+0))

查看是否有任何结果日期等于或大于 TODAY()；
如果是，将 "ALARM" 放入列 O 中，然后通过使用此值作为标识符过滤行，将其用作别处的标记。

=IF(today()>=X2,"ALARM","")

我想知道是否可以创建一个查询，其中已经将 6 个月添加到列 J 中的值，并且如果列 J 中的值[i] 大于或等于，结果列表过滤可能TODAY()。通过实现这一点，J 列将仅包含 Last N dates + 6 months AND >= TODAY()；我检查过的所有示例似乎都使用日期作为过滤器。

Answer 1

=QUERY({Sheet1!A1:A,
 ARRAYFORMULA(DATE(YEAR(Sheet1!J1:J), MONTH(Sheet1!J1:J)+6, DAY(Sheet1!J1:J)))}, 
 "select Col1,Col2,'ALARM' 
  where Col1 is not null 
    and Col2 >=date '"&TEXT(TODAY(), "yyyy-mm-dd")&"' 
  label Col2'ABCD', 'ALARM''alarm'
  format Col2 'dd-mmm-yyyy'", 1)

Answer 2

=QUERY({FleetStatus!A1:D, ARRAYFORMULA(
 DATE(YEAR(FleetStatus!J1:J), MONTH(FleetStatus!J1:J)+6, DAY(FleetStatus!J1:J)))}, 
 "select Col1,Col5,'ALARM' 
  where Col1 is not null 
    and Col1 !='IVAN GUBKIN' 
    and Col1 !='VYACHESLAV TIKHONOV'
    and Col4 != 'L'
    and Col5 <=date '"&TEXT(TODAY(), "yyyy-mm-dd")&"' 
  label Col5'+6M', 'ALARM''Alarm'
  format Col5 'dd-mmm-yyyy'", 1)

包含日期操作的查询函数 [DATE + X 月数]

Query function to contain date operations [DATE + X number of months]

google-sheets

google-query-language