“如何修复 `删除 SerializeJSON() 的默认字母顺序 `

Question

我正在尝试将序列化数据添加到第三方 API 的请求中，这需要维护特定的数据顺序，但是 SerializeJSON 按字母顺序排序，这破坏了第三方 API。谁能帮我弄明白

输入：

<cfset data ={
                "Booking": {
                    "ActionCode":"DI",
                    "AgencyNumber":"23",
                    "Touroperator":"TVR",
                    "BookingNumber":"323",
                },
                "Payment": {
                    "__type":"paymenttype",
                    "PaymentProfile": {
                        "Value": 4,
                        "Manual": false
                    },
                    "PaymentType": 4,
                    "PaymentAction":2,
                    "Details": {
                        "IBAN": "DE02120300000000202051",
                        "BIC": "BYLADEM1001"
                    }
                },
                "Login":{
                    "UserCode": "usercode",
                    "Password": "password"
                }
            }>

当此方法 SerializeJSON() 用于我的数据时：

SerializeJSON(data)

当前输出

"{"Booking":{"Touroperator":"TVR","ActionCode":"DI","BookingNumber":"323","AgencyNumber":"23"},"Login":{"UserCode":"usercode","Password":"password"},"Payment":{"PaymentProfile":{"Manual":false,"Value":4},"PaymentType":4,"PaymentAction":2,"__type":"paymenttype","Details":{"BIC":"BYLADEM1001","IBAN":"DE02120300000000202051"}}}"

预期输出：

"{"Booking":{"ActionCode":"DI","AgencyNumber":"23","Touroperator":"TVR","BookingNumber":"323",},"Payment":{"__type":"paymenttype","PaymentProfile":{"Value":4,"Manual":false},"PaymentType":4,"PaymentAction":2,"Details":{"IBAN":"DE02120300000000202051","BIC":"BYLADEM1001"}},"Login":{"UserCode":"usercode","Password":"password"}}"

Answer 1

ColdFusion 中的结构是无序的 HashMap，因此根本没有顺序。您可以使用 structNew("Ordered")（在 ColdFusion 2016 中引入）来保持插入顺序。不幸的是，您不能再使用文字语法了，但我假设您无论如何都在动态生成数据。

<cfset data = structNew("Ordered")>

<cfset data["Booking"] = structNew("Ordered")>
<cfset data["Booking"]["ActionCode"] = "DI">
<cfset data["Booking"]["AgencyNumber"] = "TVR">
<cfset data["Booking"]["BookingNumber"] = "323">

<cfset data["Payment"] = structNew("Ordered")>
<cfset data["Payment"]["__type"] = "paymenttype">
<cfset data["Payment"]["PaymentProfile"] = structNew("Ordered")>
<cfset data["Payment"]["PaymentProfile"]["Value"] = 4>
<cfset data["Payment"]["PaymentProfile"]["Manual"] = false>

etc.

如果您卡在较旧的 ColdFusion 版本上，则必须使用 Java 的 LinkedHashMap。

<cfset data = createObject("java", "java.util.LinkedHashMap")>

<cfset data["Booking"] = createObject("java", "java.util.LinkedHashMap")>
<cfset data["Booking"]["ActionCode"] = "DI">
<cfset data["Booking"]["AgencyNumber"] = "TVR">
<cfset data["Booking"]["BookingNumber"] = "323">

<cfset data["Payment"] = createObject("java", "java.util.LinkedHashMap")>
<cfset data["Payment"]["__type"] = "paymenttype">
<cfset data["Payment"]["PaymentProfile"] = createObject("java", "java.util.LinkedHashMap")>
<cfset data["Payment"]["PaymentProfile"]["Value"] = 4>
<cfset data["Payment"]["PaymentProfile"]["Manual"] = false>

etc.

但请注意：LinkedHashMap 区分大小写（并且还区分类型：如果您的键是数字，这很重要！）。

<cfset data = createObject("java", "java.util.LinkedHashMap")>

<cfset data["Test"] = "">
<!---
    accessing data["Test"] = works
    accessing data["test"] = doesn't work
    accessing data.Test    = doesn't work
--->

您可能会遇到的另一个问题：由于 ColdFusion 的内部类型转换，serializeJSON() 可能会以一种意想不到的方式将数字和布尔值串化。类似于：

<cfset data = structNew("Ordered")>
<cfset data["myBoolean"] = true>
<cfset data["myInteger"] = 123>

很容易变成这样：

{
    "myBoolean": "YES",
    "myInteger": 123.0
}

（注意：上面的文字语法可以完美地工作，但如果您将值作为 variables/arguments 传递，最终会发生转换。）

最简单的解决方法是在序列化之前显式转换值：

<cfset data = structNew("Ordered")>
<cfset data["myBoolean"] = javaCast("boolean", true)>
<cfset data["myInteger"] = javaCast("int", 123)>

“如何修复 `删除 SerializeJSON() 的默认字母顺序 `

"How to fix `remove default alphabetical ordering of SerializeJSON() `

coldfusion

cfml