数据转换工具推荐

Question

我在 Power BI 中有大量原始故障数据。

code    time                    status  
x123    2019-04-22T23:57:00     ok  
x123    2019-04-23T01:00:00     faulty  
x123    2019-04-23T02:00:00     ok  
x123    2019-04-23T23:00:00     faulty  
x123    2019-04-24T01:00:00     ok

我需要对此进行转换以显示某个项目在给定日期处于故障状态的时间。因此，在 23 日，该项目在 1 点到 2a.m 之间处于故障状态，然后在晚上 11 点到午夜过后再次处于故障状态。

code    day         % of day faulty  
x123    23/04/2019  8.30%           (2 hours)

我可以在 Power BI 中轻松完成此操作还是应该使用其他工具（例如 Azure 数据工厂）？

Answer 1

将以下计算列添加到您的 table：

Report Date = Table1[time].[Date]

Fault Duration = 
VAR CurrentTime = Table1[time]
VAR CurrentCode = Table1[code]
VAR PreviousTime = 
    CALCULATE ( 
        MAX ( Table1[time] ),
        FILTER ( 
            Table1,
            Table1[time] < CurrentTime && 
            Table1[code] = CurrentCode
        )
    )
VAR NextTime = 
    CALCULATE ( 
        MIN ( Table1[time] ),
        FILTER ( 
            Table1,
            Table1[time] > CurrentTime && 
            Table1[code] = CurrentCode
        )
    )
VAR FaultyFrom = 
    IF(
        Table1[status] = "faulty",
        Table1[time],
        IF (
            DAY(PreviousTime) = DAY(Table1[time]),
            BLANK(),
            Table1[time].[Date]
        )
    )
VAR FaultyTo = 
    IF ( 
        Table1[status] = "ok",
        Table1[time],
        IF (
            DAY(NextTime) = DAY(Table1[time]),
            NextTime,
            Table1[time].[Date] + 1
        )
    )
RETURN
    IF(
        ISBLANK ( PreviousTime ) || ISBLANK ( NextTime ) || ISBLANK ( FaultyFrom ),
        BLANK(),
        FaultyTo - FaultyFrom
    )

现在创建措施：

Faulty Hours = SUM ( Table1[Fault Duration] )

Faulty % Day = 
    IF ( 
        HASONEVALUE ( Table1[Report Date] ),
        DIVIDE ( 
            [Faulty Hours],
            DISTINCTCOUNT ( Table1[code] ),
            BLANK()
        ),
        BLANK()
    )

输出：

请参阅 https://pwrbi.com/so_55825688/ 以获取工作示例 PBIX 文件

数据转换工具推荐

Tool recommendation for data transform

dax

powerbi

azure-data-factory