x 轴上带有日期的双向图

Question

我想制作一个 twoway 条形图，根据日期绘制数字。

我想操纵 x-axis 的长度以及标签和刻度。我尝试在 xscale() 和 xlabel() 选项中输入不同格式的日期，但不断出现以下错误：

range() invalid - invalid numlist error

和

invalid label specifier

我尝试输入不同格式的日期：

clear

input date number 
16743 116
16835   384
17034   152
17113   267
17191   939
17246   372
17265   443
17302   406
17498   210
end
format date %tdnn/dd/CCYY

twoway bar number date , ///
xscale(range(11/3/2005 (100) 11/28/2007)) ///
 xlabel(11/3/2005 1/25/2007  11/28/2007)

我还尝试了以下方法：

twoway bar number date , ///
 xlabel(mdy(11,3,2005) mdy(1,25,2007)   mdy(11,28,2007) , format(%tdnn/dd/CCYY))

如何引用 xscale() 和 xlabel() 中的日期？

我希望日期的格式与 x-axis 变量的格式相同。

Answer 1

您需要计算相应的日期函数：

clear

input date number 
16743 116
16835   384
17034   152
17113   267
17191   939
17246   372
17265   443
17302   406
17498   210
end
format date %tdnn/dd/CCYY

twoway bar number date, xlabel(`=daily("11/3/2005", "MDY")'    ///
                               `=daily("1/25/2007", "MDY")'    ///
                               `=daily("11/28/2007", "MDY")',  ///
                                format(%tdnn/dd/CCYY))

这可以像上面那样即时完成，也可以使用本地宏。

x 轴上带有日期的双向图

twoway graph with date on x-axis

date

xscale

stata