如果在 power point 表中发现空单元格并且在使用 vba 的幻灯片中发出警报

Question

如果在电源插座的每个 table 中发现空单元格，我必须找到并提醒。

我找到了下面的代码 here，但它不起作用，而且不应该为所有 table 找到，而不是为选定的代码找到。

    Sub CheckTableCells()

    Dim oCell As Cell
    Dim oRow As Row
    Dim MyRange As Range

    For Each oRow In Selection.Tables(1).Rows
        For Each oCell In oRow.Cells
            If Selection.Text = Chr(13) & Chr(7) Then
                oCell.Select
                MsgBox oCell.RowIndex & " " & oCell.ColumnIndex & " is empty."
            End If
        Next oCell
    Next oRow

    End Sub

请任何人帮助我。

Answer 1

此代码遍历活动演示文稿中的每张幻灯片，并在每张幻灯片中检查幻灯片上的每个形状是否包含 table，如果包含，则检查每个单元格是否为空白。干杯。

Sub CheckTableCells()

    Dim vSlide As Slide
    Dim vShape As Shape
    Dim vRow As Long
    Dim vColumn As Long

    For Each vSlide In Application.ActivePresentation.Slides
        For Each vShape In vSlide.Shapes
            If vShape.HasTable Then
                For vRow = 1 To vShape.Table.Rows.Count
                    For vColumn = 1 To vShape.Table.Columns.Count
                        If vShape.Table.Cell(vRow, vColumn).Shape.TextFrame.TextRange.Text = "" Then
                            MsgBox vSlide.Name & " Table: """ & vShape.Name & """ cell (" & vRow & "," & vColumn & ") is blank."
                        End If
                    Next
                Next
            End If
        Next
    Next

End Sub

如果在 power point 表中发现空单元格并且在使用 vba 的幻灯片中发出警报

Alert if empty cell found in power point tables and in which slide using vba

powerpoint

vba