F# 泛型/函数重载语法

Question

我对如何在没有像 ('a -> 'a)

这样的显式类型声明的情况下将函数标记为泛型感到困惑

let add a b = a + b

这给了我们

val add : a:int -> b:int -> int

但是我们可以立即调用

add "Hello " "World!"

现在 add 的值为

val add : a:string -> b:string -> string
val it : string = "Hello World!"

如果我们再调用

add 2 3 // then we get
error: This expression was expected to have type string but here has type int

如何确保一个函数适用于所有类型，这些类型具有 (+) 定义的函数

Answer 1

如果我理解正确，请使用内联：

let inline add a b = a + b

add 2 3 |> printfn "%A"
add "Hello " "World!" |> printfn "%A"

打印：

5
"Hello World!"

Link: http://ideone.com/awsYNI

Answer 2

成功inline

let inline add a b = a + b
(*
val inline add :
  a: ^a -> b: ^b ->  ^c
    when ( ^a or  ^b) : (static member ( + ) :  ^a *  ^b ->  ^c)
*)
add "Hello " "World!"
// val it : string = "Hello World!"
add 2 3
// val it : int = 5

Answer 3

这是壁橱里F#尴尬的骨架。

试试这个：

> let mapPair f (x,y) = (f x, f y)
val mapPair : f:('a -> 'b) -> x:'a * y:'a -> 'b * 'b

完全通用！显然，函数应用程序和元组有效。

现在试试这个：

> let makeList a b = [a;b]
val makeList : a:'a -> b:'a -> 'a list

嗯，也是通用的。这个怎么样：

> let makeList a b = [a + b]
val makeList : a:int -> b:int -> int list

啊哈，一旦我在那里有一个 (+)，由于某种原因它就变成了 int。
让我们继续玩吧：

> let inline makeList a b = [a + b]
val inline makeList :
  a: ^a -> b: ^b ->  ^c list
    when ( ^a or  ^b) : (static member ( + ) :  ^a *  ^b ->  ^c)

嗯，有趣。事实证明，如果我创建函数 inline，那么 F# 确实认为它是通用的，但它也给了它这个奇怪的 when 子句，并且我的通用参数有这个奇怪的 ^ 符号而不是通常的勾号。
这种奇怪的语法称为 "statically resolved type parameters"（请参阅以了解一些连贯的解释），其基本思想是函数 (+) 要求其参数定义 static member (+)。让我们验证一下：

> let x = 0 :> obj
  let y = 0 :> obj
  let z = x + y
Script1.fsx(14,13): error FS0001: The type 'obj' does not support the operator '+'

> type My() =
     static member (+)( a:My, b:My ) = My()
  let x = My()
  let y = My()
  let z = x + y
val x : My
val y : My
val z : My

现在，问题是 CLR 不支持这种泛型参数（即 "any type, as long as it has such and such members"），因此 F# 必须伪造它并解决这些问题在编译时调用。但正因为如此，任何使用此功能的方法都无法编译为真正的通用 IL 方法，因此必须单态化（由 inline 启用）。

但是，要求每个使用算术运算符的函数都被声明是很不方便的 inline，不是吗？因此，F# 又走了一个额外的步骤，并尝试根据它们稍后在代码中的实例化方式来修复这些静态解析的泛型参数。这就是为什么你的函数一旦与 string 一起使用就变成 string->string->string 的原因。

但是如果您标记您的函数 inline，F# 将不必修复参数，因为它不必将函数编译为 IL，因此您的参数保持不变：

> let inline add a b = a + b
val inline add :
   a: ^a -> b: ^b ->  ^c
      when ( ^a or  ^b) : (static member ( + ) :  ^a *  ^b ->  ^c)

F# 泛型/函数重载语法

F# generics / function overloading syntax

generics

f#

types

function