当输出模式设置为 LOW 时 LED 不会关闭

Question

我正在制作一个使用超声波距离传感器的报警系统。它可以使用遥控器进行布防和撤防，我希望在撤防时绿色 LED 灯亮起，而在布防时红色 LED 灯亮起。红色 LED 工作正常，但绿色 LED 一直亮着。

我试过把点亮绿色led的那一行注释掉，但是好像默认是点亮的，所以当我启动程序的时候，它已经点亮了，不会熄灭。有问题的代码在底部附近，标有 //HERE

的注释

#include "IRremote.h"
#include "SR04.h"
#define TRIG_PIN 12
#define ECHO_PIN 11
SR04 sr04 = SR04(ECHO_PIN,TRIG_PIN);
long distance;

int receiver = 10;
IRrecv irrecv(receiver);     // create instance of 'irrecv'
decode_results results;      // create instance of 'decode_results'

int buzzer = 3;
int red_led = 2;
int green_led = 0;

bool can_sense = false;
bool release_pressed = false;
bool alarm_off = false;
/*-----( Function )-----*/
void translateIR() // takes action based on IR code received

// describing Remote IR codes 

{

  switch(results.value)

  {
  case 0xFFA25D: Serial.println("POWER"); alarm_off = true; break;
  case 0xFFE21D: Serial.println("FUNC/STOP"); break;
  case 0xFF629D: Serial.println("VOL+"); break;
  case 0xFF22DD: Serial.println("FAST BACK");    break;
  case 0xFF02FD: Serial.println("PAUSE"); release_pressed = true;    break;
  case 0xFFC23D: Serial.println("FAST FORWARD");   break;
  case 0xFFE01F: Serial.println("DOWN");    break;
  case 0xFFA857: Serial.println("VOL-");    break;
  case 0xFF906F: Serial.println("UP");    break;
  case 0xFF9867: Serial.println("EQ");release_pressed = false;    break;
  case 0xFFB04F: Serial.println("ST/REPT");    break;
  case 0xFF6897: Serial.println("0");    break;
  case 0xFF30CF: Serial.println("1");    break;
  case 0xFF18E7: Serial.println("2");    break;
  case 0xFF7A85: Serial.println("3");    break;
  case 0xFF10EF: Serial.println("4");    break;
  case 0xFF38C7: Serial.println("5");    break;
  case 0xFF5AA5: Serial.println("6");    break;
  case 0xFF42BD: Serial.println("7");    break;
  case 0xFF4AB5: Serial.println("8");    break;
  case 0xFF52AD: Serial.println("9");    break;
  case 0xFFFFFFFF: Serial.println(" REPEAT");break;  

  default: 
    Serial.println(" other button   ");

  }// End Case

  delay(100);
}

void setup() {
   Serial.begin(9600);
   pinMode(buzzer,OUTPUT);
   pinMode(red_led,OUTPUT);
   pinMode(green_led,OUTPUT);
   irrecv.enableIRIn();


}

void loop() {

    if (irrecv.decode(&results)) // have we received an IR signal?

  {
    translateIR(); 
    irrecv.resume(); // receive the next value
  }

  distance = sr04.Distance();
  if (distance < 70)
  {
    can_sense = true;
  }

  if (can_sense==true and release_pressed==false)
  {
    while (alarm_off==false)
    {
      digitalWrite(buzzer,HIGH);
      digitalWrite(red_led,HIGH);
      delay(500);
      digitalWrite(buzzer,LOW);
      digitalWrite(red_led,LOW);
      delay(250);

    if (irrecv.decode(&results)) // have we received an IR signal?

  {
    translateIR(); 
    irrecv.resume(); // receive the next value
  }
    }
  }
  if (release_pressed==false) //HERE
  {
    digitalWrite(red_led,HIGH);
    digitalWrite(green_led,LOW); // This should turn off the green led, but it doesn't
  }

  if (release_pressed==true)
  {
    digitalWrite(red_led,LOW);
    digitalWrite(green_led,HIGH);
  }

  alarm_off = false;
  can_sense = false;
}

感谢您的帮助:)

Answer 1

Uno 上的引脚 0 和 1 用于串行通信。

一旦你做了 Serial.begin(9600);，你就为串行通信启用了这些引脚，所以你不能将它们也用作标准数字引脚。

只需为绿色 LED 使用另一个引脚。

当输出模式设置为 LOW 时 LED 不会关闭

LED Won't turn off when output mode is set to LOW

arduino

led

arduino-uno