向脚本添加警报条件

Question

交叉零 (0) 条件存在，但我想添加标记波峰和波谷峰值的条件。换句话说，条形图变成栗色（深红色）或深绿色。

这是另一个用户的 public 代码，我认为这对我们所有使用 tradingview 的人都很有价值。

length = input(20, title="BB Length")
mult = input(2.0,title="BB MultFactor")
lengthKC=input(20, title="KC Length")
multKC = input(1.5, title="KC MultFactor")

useTrueRange = input(true, title="Use TrueRange (KC)", type=bool)

// Calculate BB
source = close
basis = sma(source, length)
dev = multKC * stdev(source, length)
upperBB = basis + dev
lowerBB = basis - dev

// Calculate KC
ma = sma(source, lengthKC)
range = useTrueRange ? tr : (high - low)
rangema = sma(range, lengthKC)
upperKC = ma + rangema * multKC
lowerKC = ma - rangema * multKC

sqzOn  = (lowerBB > lowerKC) and (upperBB < upperKC)
sqzOff = (lowerBB < lowerKC) and (upperBB > upperKC)
noSqz  = (sqzOn == false) and (sqzOff == false)

val = linreg(source  -  avg(avg(highest(high, lengthKC), lowest(low, 
lengthKC)),sma(close,lengthKC)), lengthKC,0)

bcolor = iff( val > 0, 
        iff( val > nz(val[1]), lime, green),
        iff( val < nz(val[1]), red, maroon))
scolor = noSqz ? blue : sqzOn ? black : gray 
plot(val, color=bcolor, style=histogram, linewidth=4)
plot(0, color=scolor, style=cross, linewidth=2)

Answer 1

您可以在末尾添加：

peak = bcolor == green and bcolor[1] == lime
trough = bcolor == maroon and bcolor[1] == red
bgcolor(color = peak ? lime : trough ? red : na)
alertcondition(peak, "Peak", "Peak")
alertcondition(trough, "Trough", "Trough")

向脚本添加警报条件

Adding alert condition to script

alert

pine-script