如何在 PowerBI 查询中正确使用可变月份列？

Question

我有一个性能监控 table，其中垂直列出用户，然后 header 列出月份。这些月份是在 12 个月的滚动中动态生成的 window。在每个月的月初，一个月从查询的后面消失，另一个出现在前面。月初后，我收到以下错误，直到我手动 re-run 报告： The '<#MONTH>' column does not exist in the rowset. 其中 '<#MONTH>' 是被丢弃的月份，例如如果是 2019 年 9 月，则为 'August 2018'.

我尝试将 window 添加到查询中，将查询的开始提前一天，以尝试消除感知到的竞争条件。这没有用。

这是我目前的 M 查询：

let
    Source = US_TOTALS,
    #"Appended Query" = Table.SelectRows(Table.Combine({Source, CA_TOTALS}), each [DATELASTFULFILLMENT] >= #"This Year"),
    #"Reordered Columns" = Table.ReorderColumns(#"Appended Query",{"SALESMAN", "RegionName", "DATELASTFULFILLMENT", "Total Sales", "Customer", "GROUP"}),
    #"Inserted Start of Month" = Table.AddColumn(#"Reordered Columns", "StartOfMonth", each Date.StartOfMonth([DATELASTFULFILLMENT]), type date),
    #"Reordered Columns1" = Table.ReorderColumns(#"Inserted Start of Month",{"SALESMAN", "RegionName", "DATELASTFULFILLMENT", "Total Sales", "StartOfMonth", "GROUP", "Customer"}),
    #"Removed Columns" = Table.RemoveColumns(#"Reordered Columns1",{"Customer"}),
    #"Date One" = Date.AddMonths(Date.StartOfMonth(Date.AddDays(DateTime.Date(DateTime.LocalNow()),1)),1),
    #"Date Two" = Date.AddYears(Date.AddMonths(Date.StartOfMonth(Date.AddDays(DateTime.Date(DateTime.LocalNow()),1)),0),-1),
    #"Filtered Rows" = Table.SelectRows(#"Removed Columns", each [DATELASTFULFILLMENT] < Date.AddMonths(Date.StartOfMonth(DateTime.Date(DateTime.LocalNow())),1) and [DATELASTFULFILLMENT] >= Date.AddYears(Date.AddMonths(Date.StartOfMonth(DateTime.Date(DateTime.LocalNow())),0),-1)),
    //#"Filtered Rows" = Table.SelectRows(#"Removed Columns", each Date.From([DATELASTFULFILLMENT]) < #"Date One" and Date.From([DATELASTFULFILLMENT]) >= #"Date Two"),
    #"Grouped Rows" = Table.Group(#"Filtered Rows", {"SALESMAN", "RegionName", "StartOfMonth", "GROUP"}, {{"Total", each List.Sum([Total Sales]), type number}}),
    #"Reordered Columns2" = Table.ReorderColumns(#"Grouped Rows",{"SALESMAN", "RegionName", "GROUP", "StartOfMonth", "Total"}),
    #"Inserted Month Name" = Table.AddColumn(#"Reordered Columns2", "Month Name", each Date.MonthName([StartOfMonth]), type text),
    #"Inserted Year" = Table.AddColumn(#"Inserted Month Name", "Year", each Date.Year([StartOfMonth]), type number),
    #"Merged Columns" = Table.CombineColumns(Table.TransformColumnTypes(#"Inserted Year", {{"Year", type text}}, "en-US"),{"Month Name", "Year"},Combiner.CombineTextByDelimiter(" ", QuoteStyle.None),"Month"),
    #"Removed Columns2" = Table.RemoveColumns(#"Merged Columns",{"StartOfMonth", "GROUP"}),
    #"Grouped Rows1" = Table.Group(#"Removed Columns2", {"SALESMAN", "Month", "RegionName"}, {{"Total", each List.Sum([Total]), type number}}),
    #"Sorted Rows" = Table.Sort(#"Grouped Rows1",{{"SALESMAN", Order.Ascending}}),
    #"Pivoted Columns" = Table.Pivot(#"Sorted Rows", List.Distinct(#"Sorted Rows"[Month]), "Month", "Total", List.Sum),
    Columns = List.RemoveFirstN(Table.ColumnNames(#"Pivoted Columns"),2),
    #"Replaced Value" = Table.ReplaceValue(#"Pivoted Columns",null,0,Replacer.ReplaceValue,Columns),
    #"Changed Type" = Table.TransformColumnTypes(#"Replaced Value",List.Transform(Columns, each {_, Currency.Type })),
    #"Merged Queries" = Table.NestedJoin(#"Changed Type",{"SALESMAN"},USER_MAPPING_COMBINED,{"USERNAME"},"USER_MAPPING_COMBINED",JoinKind.LeftOuter),
    #"Expanded USER_MAPPING" = Table.ExpandTableColumn(#"Merged Queries", "USER_MAPPING_COMBINED", {"NAME"}, {"NAME"})
in
    #"Expanded USER_MAPPING"

预期结果：查询正常刷新

实际结果： The '<#MONTH>' column does not exist in the rowset. 的查询错误其中 '<#MONTH>' 是被删除的月份，例如如果是 2019 年 9 月，则为 'August 2018'.

截图供参考：

Answer 1

好的，我将对此进行第二次尝试。如果我偏离了基地，我深表歉意。但是让我举个例子来模拟你的错误。

let
    Seed = Number.Mod(Number.Round(Time.Second(DateTime.LocalNow())), 7) + 1,
    Source = List.Generate(()=> Seed, each _ < Seed + 6, each _ + 1),
    #"Converted to Table" = Table.FromList(Source, Splitter.SplitByNothing(), {"MonthNumbers"}, null, ExtraValues.Error),
    #"Added Custom" = Table.AddColumn(#"Converted to Table", "MonthNames", each Date.MonthName(#date(2019, [MonthNumbers], 1))),
    #"Pivoted Column" = Table.Pivot(#"Added Custom", List.Distinct(#"Added Custom"[MonthNames]), "MonthNames", "MonthNumbers", List.Sum)
in
    #"Pivoted Column"

因此，这将创建一个 table，如下所示：

但是每一秒，画面都会移动一个月。因此，如果您每秒刷新一次预览，您将看到帧幻灯片 Jan-Jun、Feb-Jul、Mar-Aug... 当十二月是 window 中的最后一个月时，它跳回到 Jan-Jun。重点是，列在变化。

现在您尝试加载此模型。它不起作用！

从您创建具有一个列集的模型到加载列集所需的时间，这些列已经更改，因此其中一列不再存在。这就像您的月份发生变化一样。当您进入并手动加载时，您将更新您的模型并且一切都会正常工作，直到列中的下一次更改。但是当您使用计划加载执行此操作时，它不会更新模型，它只是尝试加载数据并遇到此列不匹配。

那么，我们如何在不丢失此动态命名的情况下修复它？让我们看看那个枢轴...如果我们不这样做并让我们的电源查询看起来像这样怎么办？

现在，当我们将其加载到模型中时，列名不会改变。我们像这样创建一个矩阵可视化，并做一些刷新：

没有错误，动态很好headers。

所以，这就是我认为您需要的方法。希望对你有帮助。

Answer 2

编辑：根据评论，这个答案显示了如何处理随着时间的推移改变列名的来源，这不是提问者的问题。

@RyanB 是正确的。这里正确的方法是在报告中而不是在数据模型中进行交叉表布局。一般来说，处理变化的正确方法是将它们具体化为数据，而不是模式。

原文post以下

您正在寻找 'Unpivot other columns' 转换：

Select 名称未更改的列。
使用'Unpivot other columns'变换
重命名列
将月份作为单个月份列处理

确保这发生在任何依赖于更改列名的步骤之前。

下面是两个代码相同的示例查询，但源代码具有不同的命名列：

// query1
let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("RU85FsQgCL2LdQoWUTiLL8VkJve/QliSTKF8/oK4VsO2tY8fpLyEe1aWKm3fVgvpiF7SBNLZZulQQLrD9LK339I6mAOYpoJBo5tmUOgUYNr7YwfTiUwShA/VyL/wnufhyMRqv1oHRswTJANNBshGAWN63edNkf41j4GJvzseMn67Xw==", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type text) meta [Serialized.Text = true]) in type table [ID = _t, Somethingstatic = _t, #"May-2019" = _t, #"Jun-2019" = _t, #"Jul-2019" = _t, #"Aug-2019" = _t]),
    #"Unpivoted Other Columns" = Table.UnpivotOtherColumns(Source, {"ID", "Somethingstatic"}, "Attribute", "Value"),
    #"Renamed Columns" = Table.RenameColumns(#"Unpivoted Other Columns",{{"Attribute", "Month"}}),
    #"Changed Type" = Table.TransformColumnTypes(#"Renamed Columns",{{"Value", Int64.Type}, {"ID", Int64.Type}})
in
    #"Changed Type"


// query 2
let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("RU85FsQgCL2LdQoWUTiLL8VkJve/QliSTKF8/oK4VsO2tY8fpLyEe1aWKm3fVgvpiF7SBNLZZulQQLrD9LK339I6mAOYpoJBo5tmUOgUYNr7YwfTiUwShA/VyL/wnufhyMRqv1oHRswTJANNBshGAWN63edNkf41j4GJvzseMn67Xw==", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type text) meta [Serialized.Text = true]) in type table [ID = _t, Somethingstatic = _t, #"Jun-2019" = _t, #"Jul-2019" = _t, #"Aug-2019" = _t, #"Sep-2019" = _t]),
    #"Unpivoted Other Columns" = Table.UnpivotOtherColumns(Source, {"ID", "Somethingstatic"}, "Attribute", "Value"),
    #"Renamed Columns" = Table.RenameColumns(#"Unpivoted Other Columns",{{"Attribute", "Month"}}),
    #"Changed Type" = Table.TransformColumnTypes(#"Renamed Columns",{{"Value", Int64.Type}, {"ID", Int64.Type}})
in
    #"Changed Type"

如何在 PowerBI 查询中正确使用可变月份列？

How can I properly use variable month columns in a PowerBI query?

m

powerbi