XSLT 1.0 检索或解析特定值

Question

我对下面的 XSLT 有疑问。我需要帮助来修复我的转变。我正在使用 XSLT 1.0。输入可以是 120KVA 或 120MVA 或 120.0KVA 或 120.0KV。输出我想解析成 3 个部分。即

<tns:ratedApparentPower>
          <tns:unitSymbolUnit>VA</tns:unitSymbolUnit>
          <tns:multiplier>K</tns:multiplier>
          <tns:floatValue>120.0</tns:floatValue>
 </tns:ratedApparentPower>

我目前的转型是：

   <tns:ratedApparentPower>
      <tns:unitSymbolUnit>VA</tns:unitSymbolUnit>
      <tns:multiplier>
         <xsl:value-of select="substring(translate(//ns0:ATTRIBUTE_GROUPS_ITEM[ns0:NAME='DISTXFR']/ns0:ATTRIBUTES/ns0:ATTRIBUTES_ITEM[ns0:NAME='KVA']/ns0:VALUE,'1234567890', ''),1,1)" />
      </tns:multiplier>
      <tns:floatValue>
         <xsl:value-of select="substring-before(//ns0:ATTRIBUTE_GROUPS_ITEM[ns0:NAME='DISTXFR']/ns0:ATTRIBUTES/ns0:ATTRIBUTES_ITEM[ns0:NAME='KVA']/ns0:VALUE,substring(translate(//ns0:ATTRIBUTE_GROUPS_ITEM[ns0:NAME='DISTXFR']/ns0:ATTRIBUTES/ns0:ATTRIBUTES_ITEM[ns0:NAME='KVA']/ns0:VALUE,'1234567890', ''),1,1))" />
      </tns:floatValue>
   </tns:ratedApparentPower>
</xsl:if>

生成O/P:

<tns:ratedApparentPower>
          <tns:unitSymbolUnit>VA</tns:unitSymbolUnit>
          <tns:multiplier>.</tns:multiplier>
          <tns:floatValue>120</tns:floatValue>
 </tns:ratedApparentPower>

我的疑惑是：

如何获得<tns:unitSymbolUnit>VA</tns:unitSymbolUnit>？目前，我正在对其进行硬编码。但它可以是 V 或 VA 或任何其他值
如何获得乘数？按照我目前的逻辑，当我有 120.0 时，我得到 <tns:multiplier>.</tns:multiplier> 它工作正常。
根据我目前的逻辑，我得到 <tns:floatValue>120</tns:floatValue> 而不是 120.0.
有什么方法可以缩短路径 (//ns0:ATTRIBUTE_GROUPS_ITEM[ns0:NAME='DISTXFR']/ns0:ATTRIBUTES/ns0:ATTRIBUTES_ITEM[ns0:NAME='KVA']/ns0:VALUE)，方法是将它分配给某个变量而不是每次都使用整个路径？

迈克尔我编辑了你的模板 belwo 以符合我的要求并使用 callTemplate 但收到空响应

<xsl:template name="convertFloatValues">
    <xsl:param name="floatValue1"/>
    <xsl:variable name="unit" select="translate($floatValue1, '0123456789.', '')"/>
    <unitSymbolUnit>
      <xsl:value-of select="substring($unit, 2)"/>
    </unitSymbolUnit>
    <multiplier>
      <xsl:value-of select="substring($unit, 1 , 1)"/>
    </multiplier>
    <floatValue>
      <xsl:value-of select="substring-before(., $unit)"/>
    </floatValue>
  </xsl:template>

调用模板示例。不知道我错过了什么。你能帮帮我吗

 <tns:ratedApparentPower>
                        <xsl:call-template name="convertFloatValues">
                          <xsl:with-param name="floatValue1" select="/ns0:OutputParameters/ns0:XXJEAM_ASSET_SEARCH_PKG-24GETAS/ns0:ATTRIBUTE_GROUPS/ns0:ATTRIBUTE_GROUPS_ITEM[ns0:NAME='DISTXFR']/ns0:ATTRIBUTES/ns0:ATTRIBUTES_ITEM[ns0:NAME='KVA']/ns0:VALUE"/>
                        </xsl:call-template>
                      </tns:ratedApparentPower>

输入：

<OutputParameters xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
                  xmlns="*****">
  <XXJEAM_ASSET_SEARCH_PKG-24GETAS>
      <ATTRIBUTE_GROUPS_ITEM>
        <NAME>DISTXFR</NAME>
        <ATTRIBUTES>
          <ATTRIBUTES_ITEM>
            <COLUMN_NAME>C_ATTRIBUTE3</COLUMN_NAME>
            <NAME>Volt</NAME>
            <VALUE>500</VALUE>
          </ATTRIBUTES_ITEM>
          <ATTRIBUTES_ITEM>
            <COLUMN_NAME>C_ATTRIBUTE4</COLUMN_NAME>
            <NAME>KVA</NAME>
            <VALUE>500.0KVA</VALUE>
          </ATTRIBUTES_ITEM>
         </ATTRIBUTES>
      </ATTRIBUTE_GROUPS_ITEM>

  </XXJEAM_ASSET_SEARCH_PKG-24GETAS>

</OutputParameters>

Answer 1

考虑以下示例：

XML

<input>
    <item>20KVA</item>
    <item>120MVA</item>
    <item>120.0KVA</item>
    <item>120.0KV</item>
</input>

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/input">
    <output>
        <xsl:for-each select="item">
            <xsl:variable name="unit" select="translate(., '0123456789.', '')" />
            <ratedApparentPower>
                <unitSymbolUnit>
                    <xsl:value-of select="substring($unit, 2)" />
                </unitSymbolUnit>
                <multiplier>
                    <xsl:value-of select="substring($unit, 1 , 1)" />
                </multiplier>
                <floatValue>
                    <xsl:value-of select="substring-before(., $unit)" />
                </floatValue>
            </ratedApparentPower>
        </xsl:for-each>
  </output>
</xsl:template>

</xsl:stylesheet>

结果

<?xml version="1.0" encoding="UTF-8"?>
<output>
  <ratedApparentPower>
    <unitSymbolUnit>VA</unitSymbolUnit>
    <multiplier>K</multiplier>
    <floatValue>20</floatValue>
  </ratedApparentPower>
  <ratedApparentPower>
    <unitSymbolUnit>VA</unitSymbolUnit>
    <multiplier>M</multiplier>
    <floatValue>120</floatValue>
  </ratedApparentPower>
  <ratedApparentPower>
    <unitSymbolUnit>VA</unitSymbolUnit>
    <multiplier>K</multiplier>
    <floatValue>120.0</floatValue>
  </ratedApparentPower>
  <ratedApparentPower>
    <unitSymbolUnit>V</unitSymbolUnit>
    <multiplier>K</multiplier>
    <floatValue>120.0</floatValue>
  </ratedApparentPower>
</output>

XSLT 1.0 检索或解析特定值

XSLT 1.0 to retrieve or parse a specific value

xslt

xslt-1.0