创建并填充 Raku 对象数组？

Question

我选择在 Perl 6 中重新设计我以前的一部分代码，在本例中是一个棋盘。前两个 classes 运行良好（或者至少运行良好，我知道的太少了我不能说他们的正确性），但我坚持第三个。这是代码：

#!/home/hsmyers/rakudo741/bin/perl6
# board.p6 - Beginnings of a PGN toolset. And place to start learning
#            Perl 6/Raku.
use v6d;

#!___________________________________________________________

constant $size = 4;

class Piece {
    my Str @namesOfPieces[$size] = <
        white-rook white-knight white-bishop white-queen
    >;
    my Str @abrevsOfPieces[$size] = <
        R N B Q K B N R
    >;
    my Str @symbolsOfPieces[$size] = <
        &#9814; &#9816; &#9815; &#9813; &#9812; &#9815; &#9816; &#9814;
    >;
    my Str @codeptsOfPieces[$size] = (
        "\x2656", "\x2658", "\x2657", "\x2655",
    );
    has Str $.name;
    has Str $.abrev;
    has Str $.symbol;
    has Uni $.codept;

    submethod BUILD( :$i ) {
        $!name   = @namesOfPieces[$i];
        $!abrev  = @abrevsOfPieces[$i];
        $!symbol = @symbolsOfPieces[$i];
        $!codept = @codeptsOfPieces[$i].NFC;
    }
}

class Square {
    my Int @colors[$size] = <
        1 0 1 0 1 0 1 0
    >;
    my Str @names[$size] = <
        a1 b1 c1 d1 e1 f1 g1 h1
    >;
    has Int   $.color;
    has Int   $.index;
    has Str   $.name;
    has Piece $.piece;

    submethod BUILD( :$i ) {
        $!color = @colors[$i];
        $!index = $i;
        $!name  = @names[$i];
        $!piece = Piece.new(:i($i));
    }
}

class Board is Array {
}

my $p = Piece.new(:i(0));
$p.say;
my $s = Square.new(:i(0));
$s.say;

#!___________________________________________________________

my @b := Board.new(
    Square.new(:i(0)),
    Square.new(:i(1)),
    Square.new(:i(2))
);
say @b;
say @b.WHAT;

当在 cli 中运行时，结果为：

Piece.new(name => "white-rook", abrev => "R", symbol => "♖", codept => Uni.new(0x2656).NFC)
Square.new(color => IntStr.new(1, "1"), index => 0, name => "a1", piece => Piece.new(name => "white- 
rook", abrev => "R", symbol => "♖", codept => Uni.new(0x2656).NFC))
[Square.new(color => IntStr.new(1, "1"), index => 0, name => "a1", piece => Piece.new(name => 
"white-rook", abrev => "R", symbol => "♖", codept => Uni.new(0x2656).NFC)) Square.new(color => 
IntStr.new(0, "0"), index => 1, name => "b1", piece => Piece.new(name => "white-knight", abrev => 
"N", symbol => "♘", codept => Uni.new(0x2658).NFC)) Square.new(color => IntStr.new(1, "1"), index => 
2, name => "c1", piece => Piece.new(name => "white-bishop", abrev => "B", symbol => "♗", codept => 
Uni.new(0x2657).NFC))]
(Board)

董事会class（目前是空的）是我迄今为止尝试的全部内容。令人惊讶的是（至少对我而言），它提供了一定程度的可操作性。它有不同的 "new" 和 "BUILD," 都没有提供有效的解决方案。当前的方法不起作用，考虑到实际计数将是 64 而不是 4。

我目前的想法是，我需要构建一个包含 64 个方块的数组，这反过来会创建必要的块。我试图在没有任何效果的情况下增加自我。建议？

Answer 1

从 Array 继承可能不是这里最好的设计选择；它揭示并致力于 Board 的底层表示，随着代码的发展，这将带来重构挑战。相反，我建议 Board 有一个 Square 的 Array，它是用 Square 个对象初始化的。

假设棋盘上有 $size 个方格，那么您可以这样做：

class Board {
    has @.squares[$size ** 2];

    method TWEAK() {
        @!squares = map { Square.new(i => $_ % $size) }, ^($size ** 2);
    }
}

即取范围从0到不包括$size的平方，然后将每个值映射到一个Square实例中。（我们对索引取模以避免另一个类中的索引越界。）

二维数组可能更可取：

class Board {
    has @.squares[$size;$size];

    method TWEAK() {
        @!squares = (map -> $i { Square.new(:$i) }, ^$size) xx $size;
    }
}

在这里，我们再次 map，但这次因为我们只做一维，所以我们放弃了模数。使用命名的 $i 参数意味着我们可以使用 :$i 的便利性，它是 :i($i) 的缩写（也有机会在您发布的代码中这样做）。然后，我们采用该表达式生成一行，并使用 xx 到运行 $size 次，以便获取每一列的数据。

最终，它可能不会像这样简单；也许 Square 应该采用两个构造函数参数，一个数字和一个字母，来形成它的名字。这可能最好作为 map 的 map 来完成。此外，Piece 个实例的初始化可能也希望在 Board 中发生；虽然自从我上次下国际象棋以来已经有四分之一个世纪了，但我很确定在比赛开始时并不是每个方格都有棋子。

创建并填充 Raku 对象数组？

Create and populate an array of Raku objects?

raku