Gradle不会发布神器？

Question

Gradle v4.10.2

我正在构建一个 Gradle Java 插件，它可以构建。然而，当我运行 ./gradlew publish 它什么都不做，也就是说，工件没有被发布。这是我的 build.gradle 文件（我的 gradle.properties 文件中定义了所有变量）。另外，如果我只是运行 ./gradlew publish w/o 运行ning ./gradlew build 首先，它不会运行构建阶段。我的 build.gradle 文件中缺少什么？谢谢。

plugins {
  id 'java'
  id 'maven'
  id 'maven-publish'
}
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'maven-publish'

group=project.groupId
version = '0.0.1'

jar {
  manifest {
    attributes 'artifactId': project.artifactId,
               'groupId': project.groupId,
               'version': project.version
  }
  baseName artifactId
  doLast {
    println "artifactId: $project.artifactId\ngroupId: $project.groupId\nversion: $version"
  }
}

dependencies {
  compile gradleApi()
}

// For publishigh to S3 maven repo
publishing {
  repositories {
    maven {
      url "s3://" + s3_bucket
      credentials(AwsCredentials) {
        accessKey AWS_ACCESS_KEY
        secretKey AWS_SECRET_KEY
      }
    }
  }
}

Answer 1

RTFM。我错过了发布块内的发布块。这是整个街区

publishing {
  publications {
    myLibrary(MavenPublication) {
      from components.java
    }
  }
  repositories {
    maven {
      url "s3://" + s3_bucket
      credentials(AwsCredentials) {
        accessKey AWS_ACCESS_KEY
        secretKey AWS_SECRET_KEY
      }
    }
  }
}

Gradle不会发布神器？

Gradle will not publish artifact?

gradle

gradle-plugin