我如何从 1 个变量中获取最长的单词

Question

将变量 cWord 定义为不可撤销字符。

cWord = "Web Development Tool".

需要输出

发展

当它只有 1 个变量时，如何从中获取最长的单词，

顺便说一句，这是一个 progress4gl 代码

Answer 1

DEFINE VARIABLE cWord          AS CHARACTER   NO-UNDO.
DEFINE VARIABLE iWord          AS INTEGER     NO-UNDO.
DEFINE VARIABLE iLongest       AS INTEGER     NO-UNDO.
DEFINE VARIABLE iLength        AS INTEGER     NO-UNDO.
DEFINE VARIABLE iLongestLength AS INTEGER     NO-UNDO.
DEFINE VARIABLE iEntries       AS INTEGER     NO-UNDO.

ASSIGN cWord = "Web Development Tool"

       iEntries = NUM-ENTRIES (cWord, " ").

DO iWord = 1 TO iEntries:

    ASSIGN iLength = LENGTH (ENTRY (iWord, cWord, " ")) . 

    IF iLength > iLongestLength THEN
    DO:
        ASSIGN iLongest       = iWord
               iLongestLength = iLength .        
    END.
END.

MESSAGE ENTRY (iLongest, cWord, " ") 
    VIEW-AS ALERT-BOX INFORMATION BUTTONS OK.

Answer 2

如果您有两个长度相同的单词，这将首先 return。

DEF VAR iCount      AS INT  NO-UNDO.
DEF VAR cLongest    AS CHAR NO-UNDO.
DEF VAR cString     AS CHAR NO-UNDO INIT 'Web Development Tool'.

DO  iCount = 1 TO NUM-ENTRIES(cString,' '):
    cLongest = (IF LENGTH(ENTRY(iCount,cString,' ')) > LENGTH(cLongest) THEN ENTRY(iCount,cString,' ') ELSE cLongest).
END.

MESSAGE cLongest
    VIEW-AS ALERT-BOX INFO BUTTONS OK.

Answer 3

只因为我最喜欢的锤子是临时的-table ;-)

def var cword as longchar no-undo init "Web Development Tool".

define temp-table tt no-undo
   field cc as char
   .

temp-table tt:read-json( 
    "longchar", 
    '~{"tt":[~{"cc":"' + replace( cword, ' ', '"},~{"cc":"' ) + '"}]}'
).

for each tt by length( cc ) descending:
    message tt.cc.
    leave.
end.

https://abldojo.services.progress.com:443/#/?shareId=5e56f4a84b1a0f40c34b8c3c

我如何从 1 个变量中获取最长的单词

How do i get the longest word from 1 variable

progress-4gl

openedge