用gnuplot绘制进程树

Question

类似于这个问题here 我想在给出 PID 的地方绘制进程树，我应该能够将该进程及其 children 绘制为树。但是，我想保留 parent children 之间的关系 nodes/edges。我的意思是，任何两个 children 之间都不应该有边。坐标实际上并不重要。此外，我对其他绘图工具选项持开放态度。我尝试了上述问题的公认答案，但它链接了所有节点。

任何一种 suggestion/help 都会让我开心。

注意：我正在使用 Ubuntu

Answer 1

你没有提供太多细节你有什么和你到底想要什么。所以我假设了一些东西。当然，还有改进的余地。要了解有关绘图样式的更多信息，请在 gnuplot 控制台中检查 help points、help vectors、help labels.

代码：

### drawing a simple tree
reset session

$Children <<EOD
23
34
45
56
67
78
EOD

$Parent <<EOD
123
EOD

unset border
unset tics
Size = 8
set offsets 0.2,0.2,0.2,0.2

plot $Children u (Last=[=10=]):(1):1 w labels not, \
     '' u 0:(1):(Last/2-[=10=]):(1) w vectors nohead lc rgb "black" notitle, \
     '' u 0:(1):(Size) w p pt 7 ps var lc rgb "yellow" not, \
     '' u 0:(1):1 w labels not, \
     $Parent u (Last/2):(2):(Size) w p pt 7 ps var lc rgb "light-grey" not, \
     '' u (Last/2):(2):1 w labels center not
### end of code

结果：

加法：

实际上，您可以使用 gnuplot 绘制更复杂的树形图。幸运的是，gnuplot 允许递归函数。

输入由 3 列组成，没有 header。每个ID只有一个parent，除了一个是顶级节点。一个ID可以有几个children.

先决条件：

第 1 列包含唯一的整数 ID 号
第 2 列包含第 1 列中 child ID 的 parent ID，或顶部节点的 NaN。
第3列节点标签名称

欢迎改进。

代码：（实际上是一些"nonsense"树）

### tree diagram with gnuplot
reset session

#ID  Parent   Name
$Data <<EOD
   1    NaN   Ant
   2      1   Ape
   3      1   Ass
   4      2   Bat
   5      2   Bee
   6      2   Cat
   7      3   Cod
   8      3   Cow
   9      3   Dog
  10      7   Eel
  11      7   Elk
  12      7   Emu
  13      9   Fly
  14      9   Fox
  15      4   Gnu
  16      1   Hen
  17     16   Hog
  18     12   Jay
  19     12   Owl
  20     15   Pig
  21     15   Pug
  22     12   Ram
  23     14   Rat
  24     12   Sow
  25      7   Yak
EOD

# put datablock into strings
IDs = Parents = Names = ''
set table $Dummy
    plot $Data u (IDs = IDs.strcol(1).' '): \
                 (Parents = Parents.strcol(2).' '): \
                 (Names = Names.strcol(3).' ') w table
unset table

# Top node has no parent ID 'NaN'
Start(n) = int(sum [i=1:words(Parents)] (word(Parents,i) eq 'NaN' ? int(word(IDs,i)) : 0))

# get list index by ID
ItemIdx(s,n) = n == n ? (tmp=NaN, sum [i=1:words(s)] ((word(s,i)) == n ? (tmp=i,0) : 0), tmp) : NaN

# get parent of ID n
Parent(n) = word(Parents,ItemIdx(IDs,n))

# get level of ID n, recursive function
Level(n) = n == n ? Parent(n)>0 ? Level(Parent(n))-1 : 0 : NaN

# get number of children of ID n
ChildCount(n) = int(sum [i=1:words(Parents)] (word(Parents,i)==n))

# Create child list of ID n
ChildList(n) = (Ch = ' ', sum [i=1:words(IDs)] (word(Parents,i)==n ? (Ch = Ch.word(IDs,i).' ',1) : (Ch,0) ), Ch )

# m-th child of ID n
Child(n,m) = word(ChildList(n),m)

# List of leaves, recursive function
LeafList(n) = (LL='', ChildCount(n)==0 ? LL=LL.n.' ' : sum [i=1:ChildCount(n)] (LL=LL.LeafList(Child(n,i)), 0),LL)

# create list of all leaves
LeafAll = LeafList(Start(0))

# get x-position of ID n, recursive function
XPos(n) = ChildCount(n) == 0 ? ItemIdx(LeafAll,n) : (sum [i=1:ChildCount(n)] (XPos(Child(n,i))))/(ChildCount(n))

# create the tree datablock for plotting
set print $Tree
    do for [j=1:words(IDs)] {
        n = int(word(IDs,j))
        print sprintf("% 3d % 7.2f % 4d % 5s", n, XPos(n), Level(n), word(Names,j))
    }
set print
print $Tree

# get x and y distance from ID n to its parent
dx(n) = XPos(Parent(int(n))) - XPos(int(n))
dy(n) = Level(Parent(int(n))) - Level(int(n))

unset border
unset tics
set offsets 0.25, 0.25, 0.25, 0.25

plot $Tree u 2:3:(dx()):(dy()) w vec nohead ls -1 not,\
        '' u 2:3 w p pt 7 ps 6 lc rgb 0xccffcc not, \
        '' u 2:3 w p pt 6 ps 6 lw 1.5 lc rgb "black" not, \
        '' u 2:3:4 w labels offset 0,0.1 center not
### end of code

结果：

Answer 2

如果我们真的对所有选项都持开放态度，我可以推荐我最喜欢的选项吗：

pstree -p <pid>
or
pstree -ap <pid>

可能会向您展示这样的内容：

foo,26943 /a/b/c/foo -i...
  └─foo1,26951 /a/b/c/foo1 -x...
      └─foo2,27103 /a/b/c/foo2 -y...

man pstree - 可以为您提供各种选项来调整您want/don不想在图表中看到的内容

用gnuplot绘制进程树

Draw process tree with gnuplot

ubuntu

gnuplot

process