尝试访问 PasswordLastChanged 时出现错误代码 0x8000500D

Question

我正在编写一个 VBScript，如果他们的密码在给定的天数内被更改，它将简单地检查 AD 中的每个用户。当我试图让它为单个用户工作时，我想出了以下工作代码：

Option Explicit

Dim objUser, strLDAPConnection, intPwdExpLimit

strLDAPConnection = "CN=Test User,OU=Test,OU=Employees,DC=domain,DC=com"

intPwdExpLimit = 90

Set objUser = GetObject("LDAP://" + strLDAPConnection)

WScript.Echo DaysSincePwdChange(objUser)

Function DaysSincePwdChange(objUserAccount)
    DaysSincePwdChange = dateDiff("d", objUserAccount.PasswordLastChanged, Now)
End Function

然后我尝试通过使用以下代码遍历测试 OU 中的所有用户来使其工作：

Option Explicit

Const strOffice = "Test"

Dim objEmployeesOU, objUser, intPwdExpLimit

intPwdExpLimit = 90

Set objEmployeesOU = GetObject("LDAP://OU=" & strOffice & _
                     ",OU=Employees,DC=domain,DC=com")

For Each objUser In objEmployeesOU
    If objUser.class = "user" Then
        If ((DaysSincePwdChange(objUser)) >= intPwdExpLimit) Then
            MsgBox(objUser & ": Password Expired.")
        Else
            MsgBox(objUser & ": Password Current.")
        End If
    End If 
Next

Function DaysSincePwdChange(objUserAccount)
    DaysSincePwdChange = dateDiff("d", objUserAccount.PasswordLastChanged, Now)
End Function

上面的代码产生了一个 0x8000500D 错误，谷歌搜索错误说它无法在缓存中找到属性（指的是 PasswordLastSet 属性，请参阅 error description link here).

知道为什么第一个代码块工作正常但第二个代码块在访问属性时出现问题吗？

Answer 1

错误代码 0x8000500d 表示 E_ADS_PROPERTY_NOT_FOUND。用户密码从未更改过，所以没有设置属性。您可以这样处理这种情况：

Function DaysSincePwdChange(objUserAccount)
    On Error Resume Next
    DaysSincePwdChange = dateDiff("d", objUserAccount.PasswordLastChanged, Now)
    If Err Then
      If Err.Number = &h8000500d Then
        DaysSincePwdChange = -1
      Else
        WScript.Echo "Unexpected Error (0x" & Hex(Err.Number) & "): " & _
          Err.Description
        WScript.Quit 1
      End If
    End If
End Function

并像这样修改检查：

passwordAge = DaysSincePwdChange(objUser)
If passwordAge >= intPwdExpLimit) Then
    MsgBox(objUser & ": Password Expired.")
ElseIf passwordAge = -1 Then
    MsgBox(objUser & ": Password never changed.")
Else
    MsgBox(objUser & ": Password Current.")
End If

尝试访问 PasswordLastChanged 时出现错误代码 0x8000500D

Error code 0x8000500D when trying to access PasswordLastChanged

vbscript

active-directory