为什么我们在 lisp 解释器中使用序列到表达式的转换？

Question

我正在阅读使用 lisp 的 Scheme 方言的 SICP。我的问题是为什么需要下面定义的序列到表达式的转换函数，它用于条件定义但不用于 if 表达式？

(define (sequence->exp seq)
    (cond ((null? seq) seq)
          ((last-exp? seq) (first-exp seq))
          (else (make-begin seq))))

(define (make-begin seq) (cons 'begin seq))

以下是不需要序列到表达式转换的 if 表达式的定义：

(define (if? exp) (tagged-list? exp 'if))
(define (if-predicate exp) (cadr exp))
(define (if-consequent exp) (caddr exp))
(define (if-alternative exp)
    (if (not (null? (cdddr exp)))
        (cadddr exp)
        'false))

(define (eval-if exp env)
  (if (true? (eval (if-predicate exp) env))
      (eval (if-consequent exp) env)
      (eval (if-alternative exp) env)))

以下是条件的定义，其谓词确实需要序列到表达式的转换。

(define (cond? exp) (tagged-list? exp 'cond))

(define (cond-clauses exp) (cdr exp))

(define (cond-else-clause? clause)
    (eq? (cond-predicate clause) 'else))

(define (cond-predicate clause) (car clause))

(define (cond-actions clause) (cdr clause))

(define (cond->if exp) (expand-clauses (cond-clauses exp)))

(define (expand-clauses clauses)
    (if (null? clauses) 
        'false ; no else clause
    (let ((first (car clauses))
         (rest (cdr clauses)))
        (if (cond-else-clause? first)
            (if (null? rest)
                (sequence->exp (cond-actions first))
                (error "ELSE clause isn't last: COND->IF"
                clauses))
            (make-if (cond-predicate first)
                     (sequence->exp (cond-actions first))
                     (expand-clauses rest))))))

Answer 1

一个 if 表达式只能计算一个 consequent 表达式或一个 alternate 表达式。但是 cond 表达式评估与条件子句相关联的表达式的序列为真。需要 sequence->exp 过程将一系列表达式转换为单个表达式。通过将序列包装在 begin 形式中，创建了一个表达式，该表达式可以被评估为 if 表达式中的结果或替代表达式。

在发布的代码中调用 sequence->exp 的目的是方便将 cond 表达式转换为 if 表达式；因此，在 cond 分支中找到的任何表达式序列都必须转换为新创建的 if 表达式中的单个表达式。

为什么我们在 lisp 解释器中使用序列到表达式的转换？

Why do we use sequence to expression conversion in lisp interpreters?

lisp

scheme

functional-programming