在 C++ 中将 HEX 字符串转换为 long

Question

我正在为 Ardunio 编写我的第一个 BLE 系统，我正在一个已经工作的系统之上构建它来控制 RGB 条带，目前，我正在使用 HEX 数字来了解我正在设置的内容哪里.

好的，重新处理问题，

#define BLE_RX 5
#define BLE_TX 4

SoftwareSerial BLE(BLE_RX, BLE_TX);

// set the startup color to white
unsigned long color = 0xFFFFFF;
// hold the last color set so we can off / on without losing prior settings
unsigned long lastColor = 0x000000;

void setup() 
{
  Serial.begin(9600);
  BLE.begin(9600);

  pinMode(GREEN_LED, OUTPUT);
  pinMode(RED_LED, OUTPUT);
  pinMode(BLUE_LED, OUTPUT);
  Serial.println("hello world");
}


void loop() {
  long r = ((color >> 16) & 0xFF);
  long g = ((color >> 8) & 0xFF);
  long b = (color & 0xFF);
  char data[100];
  analogWrite(RED_LED, r);
  analogWrite(GREEN_LED, g);
  analogWrite(BLUE_LED, b);

  readBLE();
}

long hstol(String recv){
  char c[6];
  recv.toCharArray(c, 6);
  return strtol(c, NULL, 16);
}

void readBLE(){
  if(BLE.available() > 0){
    String data = BLE.readString();
    if(data.length() == 6){
      lastColor = color;
      Serial.println(data);
      Serial.println(hstol(data));
      color = hstol(data);
    }
  }
}

当我第一次运行我的 CPP 时，LED 灯条是白色的，如果通过 BLE 我发送 FF0000（红色），我的 LED 变绿，这是我的输出

当 FF0000 应等于 16711680 时，00FF00 = 65280 且 0000FF = 255

Answer 1

您发布的代码中的错误来源：您使用的是 6 个字符的数组，而它应该是 7 个字符来保存整个 recv 字符串。您的代码当前显示未定义的行为，因为 strtol 搜索 null/whitespace 字符以完成解析，该字符从不存在于 char c[6].

的范围内

我建议使用这种方法。它只是一行，不需要额外的内存来存储一些临时字符数组。（也节省了时间，否则浪费在复制十六进制字符串上）。

void setup() {
  Serial.begin(9600);
  
  String x1 = "FF0000";
  long y1 = strtol(x1.c_str(), NULL, 16); // <--
  Serial.print(y1); // prints 16711680
  Serial.println();
  
  String x2 = "0xFF0000";
  long y2 = strtol(x2.c_str(), NULL, 0); // <--
  Serial.print(y2); // prints 16711680
  Serial.println();
  
  long y3 = strtol(x2.c_str() + 2, NULL, 16); // <--
  Serial.print(y3); // prints 16711680
  Serial.println();
}

void loop() {
    
}

在 C++ 中将 HEX 字符串转换为 long

Convert a HEX string to long in C++

c++

hex

arduino