Gnuplot 在一个具有不同颜色和破折号的折线图中组合多种值类型

Question

我有三个不同的线条，其中颜色和它们的破折号表示我想要在一个图上而不是三个图上的不同事物。我该如何实现？

set datafile separator comma
$sample <<EOD
2020-01-01,4,UK,Business
2020-02-01,4,UK,Business
2020-01-01,4,UK,Social
2020-02-01,15,UK,Social
2020-01-01,1,USA,Social
2020-02-01,25,USA,Social
EOD

set format x '%Y'
set xdata time
set timefmt "%Y-%m-%d"
plot '$sample' u 1:2 title "UK/Business" with linespoints dt 3 lw 5 pt 7 lc "red"

plot '$sample' u 1:2 title "USA/Social" with linespoints dt 3 lw 1 pt 7 lc "blue"
plot '$sample' u 1:2 title "UK/Social" with linespoints dt 3 lw 5 pt 7 lc "blue"

例如蓝色代表“社交”，lw 1（细点）代表美国。

Answer 1

请查看手册或help plot。同一绘图的绘图元素以逗号分隔。

Syntax:

  plot {<ranges>} <plot-element> {, <plot-element>, <plot-element>}

为了提高可读性，您可以使用 \ 将长代码行拆分为多行。请注意，除了回车 return/line feed.

外，同一行中 \ 之后不允许有任何字符

试试这个：

plot '$sample' u 1:2 title "UK/Business" w lp dt 3 lw 5 pt 7 lc "red", \
     '' u 1:2 title "USA/Social" w lp dt 3 lw 1 pt 7 lc "blue", \
     '' u 1:2 title "UK/Social" w lp dt 3 lw 5 pt 7 lc "blue"

加法：（一个过滤器取决于两个（字符串）列）

您可以使用三元运算符实现过滤器。检查 help ternary 和 help strcol。未通过过滤器的值将设置为 NaN。如果您仍然希望您的点与线相连，则需要 set datafile missing NaN.

代码：

### filtered data with different line colors
reset session
set datafile separator comma

$sample <<EOD
2020-01-01,4,UK,Business
2020-02-01,4,UK,Business
2020-01-01,4,UK,Social
2020-02-01,15,UK,Social
2020-01-01,1,USA,Social
2020-02-01,25,USA,Social
EOD

myTimeFmt = "%Y-%m-%d"
set format x '%d.%m.%Y' timedate
set key top left
set datafile missing NaN

myFilter(colData,colFilter1,key1,colFilter2,key2) = (strcol(colFilter1) eq key1) && (strcol(colFilter2) eq key2) ?  column(colData) : NaN

plot $sample u (timecolumn(1,myTimeFmt)):(myFilter(2,3,"UK",4,"Business")) w lp dt 3 lw 5 pt 7 lc "red" title "UK/Business", \
     '' u (timecolumn(1,myTimeFmt)):(myFilter(2,3,"USA",4,"Social")) w lp dt 3 lw 1 pt 7 lc "blue" title "USA/Social" , \
     '' u (timecolumn(1,myTimeFmt)):(myFilter(2,3,"UK",4,"Social")) w lp dt 3 lw 5 pt 7 lc "blue" title "UK/Social"
### end of code

或者如果第 2、3、4 列在 plot 命令中没有改变，则稍微缩短...

...
...
myTime(col) = timecolumn(col,myTimeFmt)
myFilter(key1,key2) = (strcol(3) eq key1) && (strcol(4) eq key2) ?  column(2) : NaN

plot $sample u (myTime(1)):(myFilter("UK","Business")) w lp dt 3 lw 5 pt 7 lc "red" title "UK/Business", \
     '' u (myTime(1)):(myFilter("USA","Social")) w lp dt 3 lw 1 pt 7 lc "blue" title "USA/Social" , \
     '' u (myTime(1)):(myFilter("UK","Social")) w lp dt 3 lw 5 pt 7 lc "blue" title "UK/Social"

结果：

Gnuplot 在一个具有不同颜色和破折号的折线图中组合多种值类型

Gnuplot combing multiple value types in one line graph with different colours and dashes

gnuplot