gnuplot：for 循环中数据文件的可变路径

Question

我想使用 for 循环在同一张图上绘制多条曲线。每个数据文件（名为 stat_coupe）位于不同的文件夹（fwal055wal055/rep16/ 和 fwal055wal055_c2/rep20/）中。 fwal055wal055 和 fwal055wal055_c2 对应模拟的名称。首先，我需要在其他文件（名为 file_fwal055wal055 和 file_fwal055wal055_c2）中获取以前的结果，一个数字 (Utau)。这要感谢命令 awk 才能成功完成。结果取决于文件：Utaufwal055wal055=10.5 和 Utaufwal055wal055_c2=12.2.

然后我需要将对应于路径fwal055wal055/rep16/的文件stat_coupe的第一列除以Utaufwal055wal055的值，并对对应的文件stat_coupe做同样的事情到具有 Utaufwal055wal055_c2 值的路径 fwal055wal055_c2/rep20/。此外，每个图都应具有特定格式，具体格式取决于模拟类型运行（fwal055wal055 或 fwal055wal055_c2）。

提出的问题减少到 2 个模拟 fwal055wal055 和 fwal055wal055_c2 和 1 个绘图，但我有大约 20 个模拟和 15 个不同的图表要绘制，这就是我想使用 for 循环的原因。

每次迭代的总结：

特定格式，
特定路径，
Utau 的特定值

我想在 for 循环的每次迭代中指示 Utau 的 wright 格式、路径和值。我在下面提出的解决方案成功地允许为每个模拟获取 Utau 的值，但代码 @path_.i 和 @format_.i 不起作用。

#!/bin/bash
for elem in fwal055wal055 fwal055wal055_c2;
do
  Utau[${elem}]=$(awk 'FNR==5{print }' file_$elem)
done

gnuplot -persist  <<-EOFMarker
format_fwal055wal055='pt 1 ps 1.0 lc 0 title "WALE"'
format_fwal055wal055_c2='pt 2 ps 1.0 lc 0 title "WALE c2"'

path_fwal055wal055='"fwal055wal055/rep16/stat_coupe"'
path_fwal055wal055_c2='"fwal055wal055_c2/rep20/stat_coupe"'

list="fwal055wal055 fwal055wal055_c2"
plot for [i in list] @path_.i u 1:($2/${Utau[${i}]}) @format_.i
EOFMarker

我想获得等同于：

的东西

plot @path_fwal055wal055 u 1:($2/${Utau[${i}]}) @format_fwal055wal055,\
@path_fwal055wal055_c2 u 1:($2/${Utau[${i}]}) @format_fwal055wal055_c2

有人可以帮我解决这个问题吗？

非常感谢，马丁

Answer 1

检查 help sprintf、help words 和 help word。我会创建两个具有相同数量项目的字符串，然后将它们与 sprintf() 组合起来。从 gnuplot 5.2 开始，你也可以用数组来做。

# Version 1
PATHS = '"fwal055wal055/rep16/stat_coupe" "fwal055wal055_c2/rep20/stat_coupe"'
FILES = "fwal055wal055 fwal055wal055_c2"

plot for [i=1:words(FILES)] sprintf("%s_%s",word(PATHS,i),word(FILES,i)) u 1:2

或者您可以为您的文件名定义一个函数，以使绘图命令简短易读。

# Version 2
PATHS = '"rep16/stat_coupe" "rep20/stat_coupe"'
FILES = "fwal055wal055 fwal055wal055_c2"

myFilename(i) = sprintf("%s/%s_%s",word(FILES,i),word(PATHS,i),word(FILES,i))

plot for [i=1:words(FILES)] myFilename(i) u 1:2

添加（经过一些澄清...）

如果我现在正确理解你的问题，下面的代码应该可以完成工作。对于 UTAUS 的提取，您在绘制之前执行一个单独的循环并将提取的值存储在一个字符串中。在绘图期间，您可以通过 word(UTAUS,i) 取回这些值。由于您进行了数学运算 column(2)/word(UTAUS,i)，gnuplot 会将它们解释为数字。检查 help words、help word、help sprintf、help every。

代码：

### extract and normalize in a loop with individual files and directories
reset session

FILES  = 'fwal055wal055 fwal055wal055_c2'
DIRS   = 'rep16 rep20'
TITLES = '"WALE" "WALE c2"'   # if you have spaces you need to put it into double quotes
UTAUS   = ''

# define functions for better readability
myExtractionFile(i) = sprintf("file_%s",word(FILES,i))
myDataFile(i) = sprintf("%s/%s/stat_coupe",word(FILES,i),word(DIRS,i))
myTitle(i) = word(TITLES,i)

# define point or line appearance. Add more if you have more files
set style line 1 pt 1 ps 1.0 lc 0
set style line 2 pt 2 ps 1.0 lc 1

# extract the UTAUs
do for [i=1:words(FILES)] {
    set table $Dummy
        plot myExtractionFile(i) u (utau=) every ::4::4 w table   # extract value row 5, column 1 (not counting header lines)
    unset table
    UTAUS = UTAUS.sprintf(" %g",utau)   # append the extracted value as string
}

plot for [i=1:words(FILES)] myDataFile(i) u 1:(column(2)/word(UTAUS,i)) ls i title myTitle(i)
### end of code

gnuplot：for 循环中数据文件的可变路径

gnuplot : variable paths to data file in a for loop

for-loop

gnuplot