后记终端中的数学乳胶字体

Question

我知道 epslatex 终端可以使用 latex 风格的字体。

但是如何在 postscript 终端中模拟数学乳胶字体？

set term postscript size 5,4
set out "test.ps"
pl [][-1.1:1.1] sin(x) t "sin {/Italics x}"
set out

在math latex 它看起来像：

看来我想要衬线字体。

Answer 1

恕我直言，这比它值得的麻烦要多得多。但是如果你真的想要，你可以下载标准 TeX 字体的 Adobe Type 1 版本用于 PostScript，特别是供 gnuplot postscript 终端使用。这是一个演示。

#
# Demonstrate use of TeX Computer Modern fonts in gnuplot PostScript terminal
# This demo requires Adobe Type 1 fonts that may not be installed on your system.
# If necessary you can download them from
#    http://mirrors.ctan.org/fonts/cm/ps-type1/bakoma/pfb/cmr10.pfb
#    http://mirrors.ctan.org/fonts/cm/ps-type1/bakoma/pfb/cmmi10.pfb
#    http://mirrors.ctan.org/fonts/cm/ps-type1/bakoma/patched-pfb/cmsy10.pfb
# 
set term post eps color fontfile 'cmr10.pfb' fontfile 'cmmi10.pfb' fontfile 'cmsy10.pfb'
set output 'cmfonts.eps'

set title "Use of TeX Computer Modern fonts in gnuplot PostScript terminal"

set label 1 'Times-Roman: {/Times-Roman abcdefghABCDEFGH}'
set label 2 'cmr10: {/cmr10 abcdefghABCDEFGH}'
set label 3 'cmmi10: {/cmmi10 abcdefghABCDEFGH} {/cmmi10 34562}'
set label 4 'cmsy10: {/cmmi10 abcdefghABCDEFGH} {/cmsy10 34562}'
set label 1 at graph 0.05,0.6 left
set label 2 at graph 0.05,0.5 left
set label 3 at graph 0.05,0.4 left
set label 4 at graph 0.05,0.3 left

set xlabel "{/cmmi10 3}"
plot [0:2*pi] sin(x) title "{/cmr10 sin({/cmmi10 3})}"

Answer 2

Serif (Times) 结合 Oblique (Italic) 也有点模拟乳胶数学的外观。

set term postscript size 5,4
set out "test.ps"
set label 1 'Serif: {/Serif abcdefghABCDEFGH}' at graph 0.05,0.5 left
set label 2 'Serif Oblique: {/SerifOblique abcdefghABCDEFGH}' at graph 0.05,0.4 left
set label 3 'Symbol: {/Symbol abcdefgh}' at graph 0.05,0.3 left
set label 4 'Symbol-Oblique: {/Symbol-Oblique abcdefgh}' at graph 0.05,0.2 left

pl [0:2*pi] sin(x) t "{/Serif sin} {/SerifItalics x}"
set out

这看起来并不完全符合我的要求，但无论如何在使用 Times 的文档中看起来可能会更好。

Oblique 的功劳归于 http://www.gnuplotting.org/postscript-terminal-with-italic-symbols/。

后记终端中的数学乳胶字体

math latex font in postscript terminal

gnuplot