OCaml 函数显然有效，但没有 return 预期结果

Question

谁能帮忙？我是 OCaml 的初学者，我正在尝试执行解包集的操作。有一组 [(1, 4); (2, 5); (3, 6)] 我想得到出口 [(1,2,3), (4,5,6)]。我使用的是我用 Haskell 测试过的脚本，它有效，但在 OCaml 中，它不显示结果。我哪里错了？我不知道我的错误在哪里。谢谢

let fst num1 num2 =
  match num1, num2 with
  | (x, y) -> x;;

let snd num1 num2 =
  match num1, num2 with
  | (x, y) -> y;;

let rec dcp_base list1 list2 list3 =
  match list1, list2, list3 with
  | (xs, ys, []) -> (xs, ys)
  | (xs, ys, z :: zs) -> dcp_base (xs @ [fst z]) (ys @ [snd z]) zs;; 

let descompact list =
  match list with
  | [] -> ([], [])
  | xs -> dcp_base [] [] xs;;

Answer 1

您的 fst 和 snd 函数实际上很奇怪，因为您将两个参数传递给 return 第一个或第二个。我猜你想获得一对中的第一个或第二个元素，所以你应该写（从最详细到最不详细）

(* too much details *)
let fst num = match num with (x, y) -> x
let snd num = match num with (x, y) -> y

(* let's use the wildcards *)
let fst num = match num with (x, _) -> x
let snd num = match num with (_, y) -> y

(* do we really need num? *)
let fst = function (x, _) -> x
let snd = function (_, y) -> y

(* do we really need to match on a single pattern? *)
let fst (x, _) = x
let snd (_, y) = y

它应该可以工作。

附带说明一下，fst 和 snd 已经存在于标准库中，但尝试自己实现它们永远不会错

第二个旁注，通常不建议在列表的末尾追加（不是尾递归，你迫使程序遍历整个列表以在末尾追加一个元素）。您可以做的是将每个新元素添加到列表的头部并反转最终列表：

let rec dcp_base list1 list2 list3 =
  match list1, list2, list3 with
  | (xs, ys, []) -> (List.rev xs, List.rev  ys)
  | (xs, ys, z :: zs) -> dcp_base (fst z :: xs) (snd z :: ys) zs;;

实际上，由于 OCaml 非常强大，您根本不需要 fst 和 snd：

let rec dcp_base list1 list2 list3 =
  match list1, list2, list3 with
  | (xs, ys, []) -> (List.rev xs, List.rev  ys)
  | (xs, ys, (x, y) :: zs) -> dcp_base (x :: xs) (y :: ys) zs;;

证明：

let rec dcp_base list1 list2 list3 =
  match list1, list2, list3 with
  | (xs, ys, []) -> (List.rev xs, List.rev  ys)
  | (xs, ys, (x, y) :: zs) -> dcp_base (x :: xs) (y :: ys) zs;; 

let descompact list =
  match list with
  | [] -> ([], [])
  | xs -> dcp_base [] [] xs;;

descompact [(1, 4); (2, 5); (3, 6)];;
- : int list * int list = ([1; 2; 3], [4; 5; 6])

Answer 2

问题是你对fst和snd的重新定义。不需要它们，因为它们已经在标准库中定义，并且在范围内具有这些名称。但他们也错了。您的实现采用两个参数，并通过创建中间元组而不是直接选择单个元组参数以迂回方式选择第一个或第二个。因此，当您将它应用于单个元组参数时，它将 return 一个期望第二个参数的部分应用函数。

您只需从代码中删除 fst 和 snd 的定义即可解决此问题，但如果您绝对想重新实现它，它应该看起来更像这样：

let fst (x, _) = x;;
let snd (_, y) = y;;

OCaml 函数显然有效，但没有 return 预期结果

OCaml function apparently works but does not return the expected result

ocaml

functional-programming

matching