使用 gnuplot 在标签中显示列值

Question

我有一个程序可以生成一个文件，其中包含粒子在盒子中的位置，数据还包含盒子内的压力（比方说每秒）。使用 gnuplot，我在循环中为粒子设置动画，但我想在标签中显示压力。可能吗？

这是文件。压力在第 4 列

我的代码：

# Titre du graphique
set title "Mouvement de particules d'Hélium (R = 3e-2 {/Helvetica=10 5) \n sur une surface de      4 {/Helvetica=10 5^{2}}"
set xlabel "L {/Helvetica=10 (5)}"
set ylabel "L {/Helvetica=10 (5)}"
set style line 2 lc rgb 'blue' pt 7 # cercle
set style fill solid 0.4
unset key
set size square
infile = 'particules.dat'
#stats infile using 1:2 name 'data' nooutput
k=21
do for [i=0:k] {
labels(x,y) = stringcolumn(3)
stats [*:*] infile using 5 name 'pression' nooutput
set label 1 sprintf("Pression : ", pression) at screen 0.2,0.9
plot infile index i using 1:2 with circles ls 2
pause 1.0
}

Answer 1

不太优雅，但你可以使用多图。使用它作为循环的核心：

set multiplot

set size 1,1
set origin 0,0

set border
set xtics; set ytics

set xlabel "L {/Helvetica=10 (5)}"
set ylabel "L {/Helvetica=10 (5)}"
set title "Mouvement de particules d'Hélium (R = 3e-2 {/Helvetica=10 5) \n sur une surface de      4 {/Helvetica=10 5^{2}}"

plot infile index i using 1:2 with circles ls 2

set border 0
unset xtics; unset ytics
unset xlabel; unset ylabel
unset title

set origin -0.35,0.395
plot infile index i u (0):(0):4 w labels

unset multiplot

您可能需要使用当前的 origin 值。

Answer 2

正如@Tom Solid 最初建议的那样，您仍然可以通过绘图 with labels 来完成。 “技巧”是使用 offset。这将给出一个标签，例如向上偏移 1.2 个字符大小。显然，有了这个，标签甚至被放置得比图形区域大。检查 help label 和 offset 选项，它也将在绘图样式 with labels 中工作，尽管它没有在文档中明确提及（参见 help labels）。此外，如果将其限制为一行，即 every ::0::0，则可以避免将许多标签打印在彼此之上，检查 help every.

如果您想要动画 GIF 文件，可以使用带有选项 animate 的 terminal gif，但是不幸的是图像质量不是很好。我建议创建单独的 PNG 框架，例如使用 term pngcairo 并使用其他软件将它们组合成动画 GIF。

代码：

### animation with label from data
reset session

# create some random test data
set print $Data
do for [p=0:10] {
    do for [i=1:50] {
        print sprintf("%.3f %.3f %.2f %.2f",rand(0)*2-1,rand(0)*2-1,0.03,p/10.)
    }
    print "\n"; print "\n"
}
set print

set size ratio -1
set xrange [-1:1]
set yrange [-1:1]
unset key
set style fill transparent solid 0.3
set title "Mouvement de particules d'Hélium (R = 3e-2 Å)\nsur une surface de 4 Å^2"
myLabel(col) = sprintf("Pression: %.2f",column(col))

do for [p=0:10] {
    plot $Data u 1:2:3 index p w circles ls 1, \
         ''    u (-1):(1):(myLabel(4)) index p every ::0::0 w labels offset 0,1.2
    pause 1.0
}

# additionally create an animated GIF file
set term gif size 400,400 animate delay 100 font ",10"
set output "myHeAtoms.gif"
do for [p=0:10] {
    plot $Data u 1:2:3 index p w circles ls 1, \
         ''    u (-1):(1):(myLabel(4)) index p every ::0::0 w labels offset 0,1.2
}
set output
### end of code

结果1：（wxt终端输出单个PNG）

结果 2： GIF 动画（好吧，图像质量不错，我不知道为什么这些点的大小明显不同）：

使用 gnuplot 在标签中显示列值

Display a column value in label with gnuplot

animation

label

gnuplot

particles