在 T-SQL 中可能使用更优雅的语句而不是 sub select

Question

我有以下代码，计算进入特定医院（[程序]）12 个月后这些客户无家可归时的独特客户数量 [ClientWHID] 和天数，请看下面。

我想知道，是否有更优雅的方式来编写这段代码？例如，要将括号 cte 中的 sub select 替换为 CASE 语句？或者在这种情况下是不可能的？

     DECLARE @BOP date = '07/01/2019'
     DECLARE @EOP date = '06/30/2020'
     DECLARE @EHRProgramWHID int = -1;  --  54500457 = SM AOT; 54200471 = SM FSP

   SELECT 
        cte.[EHRProgramWHID]
       ,cte.[ProgramName]
       ,COUNT( DISTINCT cte.[ClientWHID]) AS [# Homeless Clients 12 Mo after Enrollment]
       ,SUM (cte.[# Homeless Days]) AS [# Homeless Days 12 Mo after Enrollment]

  FROM
       (
         SELECT 
               epi.[EHRProgramWHID]
              ,prg.[ProgramName]
              ,epi.[Domain]
              ,epi.[Subdomain]
              ,epi.[ClientWHID]
              ,epi.[BeginDate]
              ,epi.[EndDate]
              ,IIF(epi.[BeginDate] < @BOP, @BOP, epi.[BeginDate]) AS [Upd_BeginDate]
              ,IIF(epi.[EndDate] > @EOP, @EOP, epi.[EndDate]) AS [Upd_EndDate]
              ,DATEDIFF(day, IIF(epi.[BeginDate] < @BOP, @BOP, epi.[BeginDate]), 
                             IIF(epi.[EndDate] > @EOP, @EOP, epi.[EndDate])) AS [# Homeless Days]

         FROM
              WHMHSA.[DomainStatusEpisodes] epi
              INNER JOIN [Dimension].[Program] prg ON epi.[EHRProgramWHID] = prg.[WHID]

         WHERE 
             NOT(  ( (epi.BeginDate < @BOP) AND (epi.EndDate < @BOP) )  OR 
                   ( (epi.BeginDate > @EOP) AND (epi.EndDate > @EOP) )  )
             AND (epi.Domain = 'Residential')
             AND (epi.Subdomain = 'Homeless')
             AND (epi.EHRProgramWHID IN (54500457, 54200471))
  
        ) cte


GROUP BY
        cte.[EHRProgramWHID]
       ,cte.[ProgramName]
   
ORDER BY
        cte.[ProgramName]

Answer 1

由于除了 EHRProgramWHID 、 ProgramName 、 ClientWHID 之外，您不使用 CTE 部分的任何列，因此无需 return 它们。

没有样本数据我无法检查，但请尝试：

 DECLARE @BOP date = '07/01/2019'
 DECLARE @EOP date = '06/30/2020'
 DECLARE @EHRProgramWHID int = -1;  --  54500457 = SM AOT; 54200471 = SM FSP

 SELECT 
    epi.[EHRProgramWHID]
   ,prg.[ProgramName]
   ,COUNT( DISTINCT epi.[ClientWHID]) AS [# Homeless Clients 12 Mo after Enrollment]
   ,SUM (DATEDIFF(day, IIF(epi.[BeginDate] < @BOP, @BOP, epi.[BeginDate]), 
                         IIF(epi.[EndDate] > @EOP, @EOP, epi.[EndDate]))) AS [# Homeless Days 12 Mo after Enrollment]

FROM WHMHSA.[DomainStatusEpisodes] epi
     INNER JOIN [Dimension].[Program] prg ON epi.[EHRProgramWHID] = prg.[WHID]
WHERE 
     NOT(  ( (epi.BeginDate < @BOP) AND (epi.EndDate < @BOP) )  OR 
           ( (epi.BeginDate > @EOP) AND (epi.EndDate > @EOP) )  )
     AND (epi.Domain = 'Residential')
     AND (epi.Subdomain = 'Homeless')
     AND (epi.EHRProgramWHID IN (54500457, 54200471))
GROUP BY
     epi.[EHRProgramWHID]
    ,prg.[ProgramName]

ORDER BY
     prg.[ProgramName]

在 T-SQL 中可能使用更优雅的语句而不是 sub select

Possible use of a more elegant statement instead of sub select, in T-SQL

tsql

case

subquery