如何将 JSON 文件序列化和反序列化为 DataTable 以填充 DataGridView？

Question

我想保存附加到用作 DataGridView 数据源的 BindingSource 的 DataTable 的值。我使用的代码来自

我设法将 DataTable 序列化为 JSON 并在 Form.FormClosing 事件中使用以下代码将其保存到文本文件中：

Dim path As String = "C:\Users\Mattia\Desktop\json.txt"   

Private Sub form1_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
    Dim json As String = JsonConvert.SerializeObject(binanceData, Formatting.Indented)
    File.WriteAllText(path, JsonConvert.SerializeObject(json, Newtonsoft.Json.Formatting.Indented))
End Sub

不幸的是，我进入 file.txt 的 JSON 字符串看起来像这样：

"[\r\n {\r\n "Index": 1,\r\n "Date": "2021-03-18T08:44:43",\r\n "Pair": "DOGE/EUR",\r\n "Type": "Limit",\r\n "Side": "Buy",\r\n "Average": 0.04815,\r\n "Price": 0.04815,\r\n "Executed": 30526.0,\r\n "Amount": 30526.0,\r\n "Total": 1469.82690\r\n },\r\n {\r\n "Index": 2,\r\n "Date": "2021-03-18T08:44:43",\r\n "Pair": "DOGE/EUR",\r\n "Type": "Limit",\r\n "Side": "Buy",\r\n "Average": 0.04815,\r\n "Price": 0.04815,\r\n "Executed": 30526.0,\r\n "Amount": 30526.0,\r\n "Total": 1469.82690\r\n }\r\n]"

这不是有效的 JSON 格式。
因此，对 DataTable 的 JSON 反序列化不起作用。

在 Form.Load 中，我使用此代码反序列化 JSON:

binanceData = TryCast(JsonConvert.DeserializeObject(path, (GetType(DataTable))), DataTable)

这会导致异常：

Newtonsoft.Json.JsonReaderException: 'Unexpected character encountered while parsing value: C. Path '', line 0, position 0.'

你有什么建议吗？谢谢

编辑：
我现在在文本文件中得到的 JSON 格式是：

[
  {
    "Index": 1,
    "Date": "2021-03-18T08:44:43",
    "Pair": "DOGE/EUR",
    "Type": "Limit",
    "Side": "Buy",
    "Average": 0.04815,
    "Price": 0.04815,
    "Executed": 30526.0,
    "Amount": 30526.0,
    "Total": 1469.82690
  }
]

Answer 1

您需要将粘贴到 DataGridView 中的数据序列化为 JSON 文件。
您的 DataGridView 的数据源是一个 DataTable。

Json.Net 序列化器可以很好地处理这个问题，反序列化器稍微少一点，它可能 misinterpret 一些类型，在这种情况下读取浮点值作为 Double 而不是 Decimal。 Integer 通常被视为 Long。

问题不大，我们可以将DataTable的auto-indexer改成TypeLong，用JsonSerializerSettings指定浮点数需要处理成Decimal ], 设置 FloatParseHandling = FloatParseHandling.Decimal.

剩下要做的是指示代码在JSON文件不包含任何数据时不要破坏当前DataTable对象。
我们还应该首先检查 JSON 文件是否存在。

最好将 JSON 文件保存到我们肯定具有写入权限的路径：这可以是 Application.CommonAppDataPath 返回的路径，因为您有 WinForms 应用程序。
此路径指向为您的应用程序保留的文件夹：

[Drive]:\ProgramData\[ApplicationName]\[ApplicationVersion]

您可以随时读取和写入此路径。

让我们添加一个指定 JSON 文件路径的字段。

Private jsonPath As String = Path.Combine(Application.CommonAppDataPath, "BinanceData.json")

初始化表单时，您是运行创建 DataTable 对象并定义其列类型的过程。
如果 JSON 文件存在并且它包含数据，我们将 JSON 反序列化为 DataTable 并将其设置为用于绑定 DataGridView 控件的 DataTable 字段，链接到 BindingSource。
否则，我们设置一个仅包含架构的空 DataTable。

需要 Json.Net 12.0.3+

这里描述了完整的过程：

Imports System.ComponentModel
Imports System.Data
Imports System.Globalization
Imports System.IO
Imports Newtonsoft.Json

Public Class SomeForm

    Private binanceSource As BindingSource = Nothing
    Private binanceData As DataTable = Nothing
    Private jsonPath As String = 
        Path.Combine(Application.CommonAppDataPath, "BinanceData.json")

    Public Sub New()
        InitializeComponent()
        ' [...]
        InitializeDataSource()
        InitializeBinanceUI()
    End Sub

    Private Sub InitializeDataSource()
        If File.Exists(jsonPath) Then
            Dim settings = New JsonSerializerSettings() With {
                .FloatParseHandling = FloatParseHandling.Decimal
            }
            Dim json = File.ReadAllText(jsonPath)
            Dim dt = JsonConvert.DeserializeObject(Of DataTable)(json, settings)
            If dt IsNot Nothing AndAlso dt.Columns.Count > 0 Then
                dt.Columns("Index").AutoIncrement = True
                dt.Columns("Index").AutoIncrementSeed = CType(dt.Rows(dt.Rows.Count - 1)("Index"), Long) + 1
                dt.Columns("Index").AutoIncrementStep = 1
                binanceData = dt
                Return
            End If
        End If

        binanceData = New DataTable("BinanceData")
        binanceData.Columns.Add(New DataColumn() With {
            .DataType = GetType(Long),
            .ColumnName = "Index",
            .AutoIncrement = True,
            .AutoIncrementSeed = 1,
            .AutoIncrementStep = 1
        })

        binanceData.Columns.Add("Date", GetType(Date))
        binanceData.Columns.Add("Pair", GetType(String))
        binanceData.Columns.Add("Type", GetType(String))
        binanceData.Columns.Add("Side", GetType(String))

        binanceData.Columns.Add("Average", GetType(Decimal))
        binanceData.Columns.Add("Price", GetType(Decimal))
        binanceData.Columns.Add("Executed", GetType(Decimal))
        binanceData.Columns.Add("Amount", GetType(Decimal))
        binanceData.Columns.Add("Total", GetType(Decimal))
    End Sub

    Private Sub InitializeBinanceUI()
        AddHandler dgvBinance.CellFormatting, AddressOf dgvBinanceCellFormatting
        binanceSource = New BindingSource(binanceData, "")
        dgvBinance.DataSource = binanceSource
        dgvBinance.Columns("Date").DefaultCellStyle.Format = "MM-dd H:mm:ss"
        dgvBinance.Columns("Average").DefaultCellStyle.Format = "N5"
        dgvBinance.Columns("Price").DefaultCellStyle.Format = "N5"
        dgvBinance.Columns("Executed").DefaultCellStyle.Format = "N1"
        dgvBinance.Columns("Amount").DefaultCellStyle.Format = "N1"
        dgvBinance.Columns("Total").DefaultCellStyle.Format = "N5"
    End Sub
End Sub

当窗体关闭时，我们将数据保存到 JSON 文件，序列化 DataTable 内容，从 FormClosing 处理程序调用 SerializeBinanceDataTable() 方法。当然，如果需要，您可以在任何其他情况下调用此方法。

Private Sub SomeForm_FormClosing(sender As Object, e As FormClosingEventArgs) Handles MyBase.FormClosing
    SerializeBinanceDataTable()
End Sub

Private Sub SerializeBinanceDataTable()
    Dim json As String = JsonConvert.SerializeObject(binanceData, Formatting.Indented)
    File.WriteAllText(jsonPath, json)
End Sub

如何将 JSON 文件序列化和反序列化为 DataTable 以填充 DataGridView？

How to serialize and deserialize JSON file into a DataTable to fill a DataGridView?

vb.net

datatable

datagridview

json.net

winforms