处理 Resume 时出错，但 Msgbox 反映错误

Question

我有两个文件（A 和 B），每个文件包含多个 sheet。我想删除某些 sheets.

当我要删除的 sheet 已经消失时出现问题。

我介绍了错误处理。有什么方法可以在遇到错误时恢复代码，同时提供动态报告，显示哪个文件不包含哪个 sheets?

我想在出现错误时继续执行代码，但报告哪个文件和哪个 sheet 有错误。

Sub Remove_sheets()
    Dim A As workbook: Set A = Workbooks("A.xlsx")
    Dim B As workbook: Set B = Workbooks("B.xlsx")
    Const NameA As String = "A"
    Const NameB As String = "B"

    On Error GoTo Handling
    Application.DisplayAlerts = False
       
    A.Worksheets("Sheet1").Delete     'can be any sheets
    B.Worksheets("Sheet5").Delete
    B.Worksheets("Sheet5 (2)").Delete

    Exit Sub
    
Handling:
    MsgBox "There is no sheet1 in " & NameA & " to be deleted"
    Application.DisplayAlerts = True
End Sub

Answer 1

像您在代码中那样使用错误处理不会达到预期的结果。由于任何删除语句都可能发生错误，因此无法知道是哪个删除语句引发了错误，因此无法准确报告。

以下是我的设置方式：

Public Sub Remove_sheets()
   Dim A As Workbook: Set A = Workbooks.Open("A.xlsx")
   Dim B As Workbook: Set B = Workbooks.Open("B.xlsx")

   Application.DisplayAlerts = False
   
   DeleteSheet "Sheet1", A
   DeleteSheet "Sheet5", B
   DeleteSheet "Sheet5 (2)", B
   
   Application.DisplayAlerts = True
End Sub

Private Sub DeleteSheet(shtName As String, wb As Workbook)
   If WorksheetExists(shtName, wb) Then
      wb.Worksheets(shtName).Delete
   Else
      MsgBox "There is no " & shtName & " in " & wb.Name & " to be deleted"
   End If
End Sub

下面的辅助函数是from this answer:

Private Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
   Dim sht As Worksheet

   If wb Is Nothing Then Set wb = ThisWorkbook
   On Error Resume Next
   Set sht = wb.Sheets(shtName)
   On Error GoTo 0
   WorksheetExists = Not sht Is Nothing
End Function

处理 Resume 时出错，但 Msgbox 反映错误

Error handling Resume but with Msgbox reflecting error

error-handling

excel

vba

dynamic