有没有办法从一个范围中索引/排列某些多个（非相邻）列？

Question

我有一个经过计算和过滤的范围，可以生成一百多列。不过我只想展示一小部分。

=INDEX(FILTER(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1NLj6NBgU2z2V2ZKjr6-tRjITpYU9E5XOoklqTCEFrPo","Database!$B:$JT43")
,
(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1NLj6NBgU2z2V2ZKjr6-tRjITpYU9E5XOoklqTCEFrPo",Tracker!B15)=Tracker!B16)
+
(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1NLj6NBgU2z2V2ZKjr6-tRjITpYU9E5XOoklqTCEFrPo",Tracker!B15)=Tracker!B15))
,,7)

公式看起来很复杂而且很长，但它只是一个标准过滤器，有两个可能的正确解决方案 - 我只是从另一个 sheet 中提取数据。它根据变量过滤掉 1400 多行。然后在过滤范围之外，它索引选定的列。

目前仅显示第7列，但我正在寻找它显示第7、255、261、256、266、262列。 按照这个顺序。

有办法吗？我环顾四周，似乎找不到语法。很高兴使用完全改变原始公式的解决方案，但 请记住，我希望最终在整个 INDEX 公式上使用 SORT 函数。

提前致谢。

sheet 示例；

https://docs.google.com/spreadsheets/d/1gj1E2lLPOz-kbGw4qB-fx9VhefN1vFbEiQHY57NaNSo/edit?usp=sharing

Answer 1

我在选项卡 'JPV_HELP' 中输入了单元格 C3

=IF($B="None","-",
QUERY(
IMPORTRANGE(
"https://docs.google.com/spreadsheets/d/1NLj6NBgU2z2V2ZKjr6-tRjITpYU9E5XOoklqTCEFrPo",
"Database!$B:$JT43"), 
"Select Col7, Col255, Col261, Col256, Col266 , Col262 
where Col266 matches '"&textjoin("|", 1, B15:B16)&"'", 1)
)

如果您想按特定列排序，您可以将其包含在查询中。

"Select Col7, Col255, Col261, Col256, Col266 , Col262 
where Col266 matches '"&textjoin("|", 1, B15:B16)&"' order by Col7 asc"

使用 'desc' 而不是 'asc' 来进行降序排序。

看看这对你有用吗？

有没有办法从一个范围中索引/排列某些多个（非相邻）列？

Is there a way to INDEX / ARRAY certain multiple (non adjacent) columns from a range?

arrays

indexing

multiple-columns

google-sheets

google-sheets-formula