如何比较重复的列并比较它们的数值范围以检查和 return 任何重叠值？

Question

这是我在此处提出的上一个问题的扩展问题： 上面的问题已得到解答，但如果我要使用和申请值超过 700 个单元格的 sheet，公式似乎会中断并出现 return 错误。 Google Sheet Link : Click Here

如题所示，是否可以使用googlesheet公式求得：

1. 遍历整个列（C 列）以查找重复项，
2. 在这些重复项中，比较其单元格旁边设置的数字范围（D 列），
3. 并检查是否有任何重叠的数字。

感谢任何提示和/或公式。

Answer 1

这是你需要的吗？

err 如果本课程的任何页面出现在两个以上的地方。例如英语的第 1 页。

公式如下：

={
  "Warning";
  ARRAYFORMULA(
    IFS(
      C3:C = "",,
      D3:D = "",,
      IFNA(
      REGEXMATCH(
        TO_TEXT(D3:D),
          "(?:^|,)"
        & VLOOKUP(
            C3:C,
            SPLIT(
              REGEXREPLACE(
                TRANSPOSE(QUERY(
                  QUERY(
                    QUERY(
                      QUERY(
                        SPLIT(
                          FLATTEN(
                            FILTER(C3:C & "♦'♥" & SPLIT(D3:D, ",") & "|", C3:C <> "", D3:D <> "")
                          ),
                          "♥"
                        ),
                        "SELECT Col1, Col2, COUNT(Col2)
                         WHERE Col2 != '|'
                         GROUP BY Col1, Col2",
                      ),
                      "SELECT Col1, Col2
                       WHERE Col3 > 1",
                      1
                    ),
                    "SELECT MAX(Col2)
                     GROUP BY Col2
                     PIVOT Col1",
                  ),,
                  10^7
                )),
                "\|\s*$|(♦'|\|)\s*",
                ""
              ),
              "♦"
            ),
            2,
          )
        & "(?:,|$)"
      ), False),
        "err",
      True,
    )
  )
}