我有将更改记录到新 sheet 的代码。我如何添加代码，将用户带到该日志 sheet 中的最新条目以添加注释？

Question

我目前有代码将所做的任何更改记录到单独的更改日志中 sheet。我需要添加代码，将用户带到更改日志中的最新条目，以便他们必须记下他们更改它的原因。我正在探索这个选项，即被带到该条目或在进行更改时出现弹出文本框，提示用户输入注释，然后该注释将与该条目一起保存在日志中。

这是我的工作代码：

Dim oldValue As String
Dim oldAddress As String

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    Dim sSheetName As String
    Data = "Data"
    Dim ssSheetName As String
    MoreData = "MoreData"
    
    If ActiveSheet.Name <> "LogDetails" Then
        Application.EnableEvents = False
        Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Value = ActiveSheet.Name & " – " & Target.Address(0, 0)
        Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 1).Value = oldValue
        Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 2).Value = Target.Value
        Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 3).Value = Environ("username")
        Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 4).Value = Now

    If ActiveSheet.Name = Data Then
        Sheets("LogDetails").Hyperlinks.Add Anchor:=Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 5), Address:="", SubAddress:="'" & Data & "'!" & oldAddress, TextToDisplay:=oldAddress
    
    ElseIf ActiveSheet.Name = MoreData Then
        Sheets("LogDetails").Hyperlinks.Add Anchor:=Sheets("LogDetails").Range("A" & Rows.Count).End(xlUp).Offset(0, 5), Address:="", SubAddress:="'" & MoreData & "'!" & oldAddress, TextToDisplay:=oldAddress
    End If

    Sheets("LogDetails").Columns("A:D").AutoFit
    Application.EnableEvents = True
    
    End If
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    
    If Target.Count > 1 Then Exit Sub
    If Target.Count = 1 Then
        oldValue = Target.Value
    End If
    oldAddress = Target.Address
End Sub

Answer 1

我忍不住做了一些重构：

为这样的作品创建一个单独的 sub-routine 总是一个好主意 - 然后从 worksheet_change-event.

调用例程

此外，我首先创建一个包含要记录的值的数组 - 然后将此数组写入 log-sheet。通常这是出于性能原因 - 此日志记录并非如此。

但如您所见：阅读和理解代码要容易得多 - 因为 reader 不必沿着长代码行“走动”以查看发生了什么。

通过为目标范围使用变量，以后 select 它很容易。

关于您的基本问题： 此代码首先要求用户使用 input-box 进行评论。如果 he/she 没有给出答案，相应的单元格将突出显示并再次要求用户发表评论。

将其放入普通模块

Public Sub addLogEntry(rgCellChanged As Range, oldValue As String, oldAddress As String)

Dim wsChanged As Worksheet
Set wsChanged = rgCellChanged.Parent

Dim wsLogData As Worksheet
Set wsLogData = ThisWorkbook.Worksheets("LogDetails")

'we don't need logging on the logsheet
If wsChanged Is wsLogData Then Exit Sub


'Get comment from user
Dim commentChange As String
commentChange = InputBox("Please enter a comment, why you made this change.", "Logging")


Application.EnableEvents = False

'Collect data to log
Dim arrLogData(6) As Variant
arrLogData(0) = wsChanged.Name & " - " & rgCellChanged.Address(0, 0)
arrLogData(1) = oldValue
arrLogData(2) = rgCellChanged.Value
arrLogData(3) = Environ("username")
arrLogData(4) = Now
arrLogData(6) = commentChange '>>> adjust the column in case your comment column is not G



'get cell to enter log data
Dim rgLogData As Range
Set rgLogData = wsLogData.Range("A" & Rows.Count).End(xlUp).Offset(1, 0)

'write data
rgLogData.Resize(, 7).Value = arrLogData

'create hyperlink
wsLogData.Hyperlinks.Add rgLogData.Offset(, 5), Address:="", SubAddress:="'" & wsChanged.Name & "'!" & oldAddress, TextToDisplay:=oldAddress

'>>> optional: activate log sheet and select comment cell
'If user hasn't entered a comment, activate logsheet and cell
If LenB(commentChange) = 0 Then
    wsLogData.Activate
    MsgBox "Please enter the comment, why you made the change.", vbExclamation, "Logging"
    rgLogData.Offset(, 6).Select
End If

Application.EnableEvents = True

End Sub

这就是你的 worksheet_change 的样子

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    addLogEntry Target, oldValue, oldAddress
End Sub

另一个优点：如果代码 reader 到达此 he/she 立即理解会发生什么（将添加一个日志条目）- 不需要阅读整个代码来理解它

我有将更改记录到新 sheet 的代码。我如何添加代码，将用户带到该日志 sheet 中的最新条目以添加注释？

I have code that logs changes into a new sheet. How can I add code that will take the user to the most current entry in that log sheet to add a note?

excel

vba