如何在 ColdFusion 中用 < 替换 <

Question

我正在使用 ColdFusion 从数据库条目创建一个 XML 文档，当创建 XML 时，< 和 > 的格式为 < 和 >。所以在创建 XML 之前，有没有办法将 < 更改为 <?

下面是代码和输出示例：

<cfquery name="messages" datasource="showcase_Uk">
     select * from t_items where pid = 2 and spid = 45
</cfquery>

<cfset myStruct = StructNew() />
<cfset mystruct.link = "http://showcase.com" />
<cfset myStruct.title = "Examples" />
<cfset mystruct.description = "Examples from UK Showcase" />
<cfset mystruct.pubDate = Now() />
<cfset mystruct.version = "rss_2.0" />
<cfset myStruct.item = ArrayNew(1) />

<cfloop query="messages">
   <cfset myStruct.item[currentRow] = StructNew()>
   <cfset myStruct.item[currentRow].guid = structNew()>
   <cfset myStruct.item[currentRow].guid.isPermaLink="YES">
   <cfset myStruct.item[currentRow].guid.value = xmlFormat(#messages.id#)>
   <cfset myStruct.item[currentRow].pubDate = createDate(year(#messages.uploadDate#), month(#messages.uploadDate#), day(#messages.uploadDate#))>
   <cfset myStruct.item[currentRow].title = xmlFormat(#messages.name#)>
   <cfset myStruct.item[currentRow].description = StructNew() />
   <cfset myStruct.item[currentRow].description.value = xmlFormat(#messages.description#)>
</cfloop>


<cffeed action="create" name="#myStruct#" overwrite="true" xmlVar="myXML">

<cffile action="write" file="e:\domains\showcase.com\wwwroot\ukshowcasefeed.xml" nameconflict="overwrite" output="#XMLFormat(myXML)#">

 <cffile action="read" file="e:\domains\showcase.com\wwwroot\ukshowcasefeed.xml" variable="myfile">

 <cfoutput>#myfile#</cfoutput>

那么这是它生成的代码的屏幕截图：

我已经尝试 ReplaceNoCase 并且根本没有改变它。我相信这可能与正则表达式有关，但我真的不知道。

Answer 1

简单回答：

写文件时不要XmlFormat()，这就是导致您看到双重编码的原因。

更长的答案：

我建议您使用映射来创建提要：

<cfquery name="messages" datasource="showcase_Uk">
  select
    id, uploadDate, name, description, 'yes' as isPermaLink
  from
    t_items
  where
    pid = 2 and spid = 45
</cfquery>

<cfset feedMeta = {
  version: "rss_2.0",
  title: "Examples",
  link: "http://showcase.com",
  publisheddate: Now(),
  description: "Examples from UK Showcase"
}>

<cfset feedMap = {
  title: "name",
  content: "description",
  publisheddate: "uploadDate",
  id: "id",
  idpermalink: "isPermaLink"
}>

<cffeed
  action="create"
  properties="#feedMeta#" columnMap="#feedMap#" query="#messages#"
  xmlvar="feedXml"
>

<cffile
  action="write"
  file="#ExpandPath('/ukshowcasefeed.xml')#" nameconflict="overwrite" charset="utf-8"
  output="#feedXml#"
>

注意 Feed 创建的简单声明方法。没有循环，没有手动创建结构，只有输入到输出的数据驱动映射。

还要注意 <cffile> 上的 charset="utf-8"，如果您不想运行陷入编码问题，那是必不可少的。

如果您修改查询使其立即具有正确的列名，那么您甚至不需要 feedMap 结构：

<cfquery name="messages" datasource="showcase_Uk">
  select
    id, 
    'yes' as idpermalink
    uploadDate as publisheddate,
    name as title,
    description as content 
  from
    t_items
  where
    pid = 2 and spid = 45
</cfquery>

<cffeed
  action="create"
  properties="#feedMeta#" query="#messages#"
  xmlvar="feedXml"
>

如何在 ColdFusion 中用 < 替换 <

How to replace < with < in ColdFusion

regex

xml

rss

coldfusion

如何在 ColdFusion 中用 < 替换 <

How to replace &lt; with < in ColdFusion

regex

xml

rss

coldfusion

How to replace < with < in ColdFusion