ADO 使用 delphi 将记录插入访问数据库

Question

我正在学习如何使用 insert into 语句，并尝试使用我的访问数据库插入一条记录。我要插入新记录的 table 具有三个字段：StockID (AutoN)、Description (Text)、Cost (Number)。我看过以前的 posts，但 posted 解决方案似乎超出了我的 Insert Into... 基本水平，这正是我感兴趣的内容。无论如何，这是我的代码。 ..

    adoQuery1.Active := true;
adoQuery1.SQL.Clear;
adoQuery1.SQL.Add('INSERT INTO Stock (StockID,Description,Cost) VALUES (4,Cheese,5)');
adoQuery1.open;
adoQuery1.Close;

它编译正常，但是当按下命令按钮调用上面的内容时，我收到以下消息：

'ADOQuery1: "Missing SQL property".'

我做错了什么？

谢谢，阿贝利斯托。你的最后一个 post 看起来确实很复杂......但是自从你的最后一个解决方案让我起来运行之后我做了我自己的小版本。它有效，所以我很高兴。我现在将重点关注使用组合框（用于字段选择）和用户值的 DELETE FROM。这是我开始工作的解决方案...;)

x:=strtoint(txtStockID.Text);
y:=txtDescription.Text;
z:=strtoCurr(txtCost.Text);

adoQuery1.SQL.Clear;
adoQuery1.SQL.Add('INSERT INTO tblStock (StockID,Description,Cost)');
adoQuery1.SQL.Add('VALUES (:StockID,:Description,:Cost)');   // ':StockID' denotes a parameter
adoQuery1.Parameters.ParamByName('StockID').Value:= x;
adoQuery1.Parameters.ParamByName('Description').Value:= y;
adoQuery1.Parameters.ParamByName('Cost').Value:= z;
adoQuery1.ExecSQL;
adoQuery1.Close;

Answer 1

使用参数比常量 SQL 语句更有效。除了我在这里的评论之外，还有一些有用的函数，我经常使用这些函数来调用带参数的 SQL 语句（也许它对你也有用）：

function TCore.ExecQuery(const ASQL: String; const AParamNames: array of string;
    const AParamValues: array of Variant): Integer;
var
    q: TADOQuery;
    i: Integer;
begin
    if Length(AParamNames) <> Length(AParamValues) then
        raise Exception.Create('There are different number of parameter names and values.');

    q := GetQuery(ASQL) as TADOQuery;
    try
        for i := Low(AParamNames) to High(AParamNames) do
            SetParamValue(q, AParamNames[i], AParamValues[i]);
        q.ExecSQL;
        Result := q.RowsAffected;
    finally
        q.Free;
    end;
end;

function TCore.GetQuery(const ASQL: String): TDataSet;
begin
    Result := TADOQuery.Create(Self);
    (Result as TADOQuery).CommandTimeout := 0;
    (Result as TADOQuery).Connection := Connection;
    (Result as TADOQuery).SQL.Text := ASQL;
end;

procedure TCore.SetParamValue(AQuery: TDataSet; const AName: string; const AValue: Variant);
var
    i: Integer;
    q: TADOQuery;
begin
    q := AQuery as TADOQuery;
    for i := 0 to q.Parameters.Count - 1 do
        if AnsiSameText(AName, q.Parameters[i].Name) then
        begin
            case VarType(AValue) of
                varString, varUString:
                    q.Parameters[i].DataType := ftString;
                varInteger:
                    q.Parameters[i].DataType := ftInteger;
                varInt64:
                    q.Parameters[i].DataType := ftLargeint;
            end;

            q.Parameters[i].Value := AValue;
        end;
end;

以及您的使用示例：

Core.ExecQuery(
  'INSERT INTO Stock (StockID, Description, Cost) VALUES (:PStockID, :PDescription, :PCost)', 
  ['PStockID', 'PDescription', 'PCost'],
  [4, 'Cheese', 5]);

ADO 使用 delphi 将记录插入访问数据库

ADO insert a record into access DB using delphi

delphi

ado