如何声明从具有过程类型参数的脚本调用的 Delphi 对象的方法

Question

在 Delphi 应用程序中运行 DWS 脚本。 Delphi 应用程序向脚本公开了一个对象实例，我们称它为 "MyApplication"。暴露的对象有一个方法，它有一个参数是一个过程。

从根本上讲，目标是让一个 Delphi 方法进行一些计算，并在回调过程表示完成时停止此计算。回调过程在脚本里面。

我通过将回调函数的名称作为字符串传递来实现这一点。除了在脚本编译时不进行类型检查外，它工作得很好。我想传递一个实际的过程，以便脚本编译器可以在编译时捕获任何错误。

怎么做？

为了帮助 reader 理解我的意思，我展示了一些 - 不起作用 - 代码：

首先是Delphi方面的简化版本：

Interface
type
    TAppCheckProc = procedure (var Done : Boolean);

TMyApplication = class(TPersistent)
published
    procedure Demo(CheckProc : TAppCheckProc);
end;

Implementation

TMyApplication.Demo(CheckProc : TAppCheckProc);
var
    Done : Boolean;
begin
    Done := FALSE;
    while not Done do begin
        // Some more code here...
        CheckProc(Done);
    end;
end;

其次，在脚本方面我有这个（也简化）：

procedure CheckProc(
    var Done : Boolean);
var
    Value : Integer;
begin
    DigitalIO.DataIn(1, Value);
    Done := (Value and 8) = 0;
end;

procedure Test;
begin
    MyApplication.Demo(CheckProc);
end;

很可能 Demo 方法参数应该以不同方式声明并且应该以不同方式调用。这就是问题...

编辑：删除了额外的 Tag 参数（简化代码时出错，这不是问题所在）。

Answer 1

我很快就把它放在一起了，它起作用了。当回调的参数不正确时，它会给出一个编译错误。您需要创建一个委托并将其用作类型。

使用独立函数的示例

dwsUnit 是用于自定义 Delphi 方法的 TdwsUnit。

procedure TMainForm.FormCreate(Sender: TObject);
var
  delegate: TdwsDelegate;
  func: TdwsFunction;
  parm: TdwsParameter;
begin
  // Create a delegate
  delegate := dwsUnit.Delegates.Add;
  delegate.Name := 'TAppCheckProc';
  parm := delegate.Parameters.Add;
  parm.Name := 'Done';
  parm.DataType := 'Boolean';
  parm.IsVarParam := True;

  // Create our function and link it to the event handler
  func := dwsUnit.Functions.Add;
  func.Name := 'Demo';
  func.OnEval := dwsUnitFunctionsDemoEval;
  parm := func.Parameters.Add;
  parm.Name := 'CheckProc';
  parm.DataType := 'TAppCheckProc';
end;

我用来测试的脚本如下：

procedure CheckProc(
    var Done : Boolean);
begin
  if Done then
    SayHello('World');
end;

Demo(CheckProc);

如果我将参数从布尔值更改为整数，我会在脚本中遇到编译错误。

我的完整性事件处理程序如下所示：

procedure TMainForm.dwsUnitFunctionsDemoEval(info: TProgramInfo);
begin
  info.Vars['CheckProc'].Call([True]);
end;

示例使用 classes

如果您想使用 classes，那么代码会略有不同。假设您正在使用 CustomClasses 演示并想使用 TEarth class 那么这将是创建方法和委托的代码。

procedure TMainForm.FormCreate(Sender: TObject);
var
  delegate: TdwsDelegate;
  method: TdwsMethod;
  parm: TdwsParameter;
begin
  // Create a delegate
  delegate := dwsUnit.Delegates.Add;
  delegate.Name := 'TAppCheckProc';
  parm := delegate.Parameters.Add;
  parm.Name := 'Done';
  parm.DataType := 'Boolean';
  parm.IsVarParam := True;

  // Create our method and link it to the event handler
  method := TdwsClass(dwsUnit.Classes.Symbols['TEarth']).Methods.Add;
  method.Name := 'Demo';
  method.OnEval := dwsUnitFunctionsDemoEval;
  parm := method.Parameters.Add;
  parm.Name := 'CheckProc';
  parm.DataType := 'TAppCheckProc';
end;

使用它的脚本是：

procedure CheckProc(
    var Done : Boolean);
begin
  if Done then
    PrintLn('Called with true')
  else
    PrintLn('Called with false');
end;

var earth: TEarth;
earth:=TEarth.Create;
earth.Demo(CheckProc);

事件处理程序如下：

procedure TMainForm.dwsUnitFunctionsDemoEval(info: TProgramInfo; ExtObject:
    TObject);
begin
  info.Vars['CheckProc'].Call([True]);
end;

与独立版本一样，更改脚本参数类型会产生 "compiler" 错误。

正如 SpeedFreak 在评论中指出的那样。您也可以通过 IDE 设计器而不是代码来完成此操作。

如何声明从具有过程类型参数的脚本调用的 Delphi 对象的方法

How to declare a method of a Delphi object called from a script having a procedure type argument

delphi

dwscript

使用独立函数的示例

示例使用 classes